squeeze.el

   1 (defgroup squeeze nil
   2   "Interact with Squeezebox media servers"
   3   :prefix "squeeze-"
   4   :group 'applications)
   5
   6 (defcustom squeeze-server-address "localhost"
   7   "Address for the Squeezebox server"
   8   :group 'squeeze)
   9 (defcustom squeeze-server-port 9090
  10   "Port number for the Squeezebox server"
  11   :group 'squeeze)
  12
  13 (defvar squeeze-mode-map
  14   (let ((map (make-sparse-keymap)))
  15     (define-key map (kbd "TAB") 'completion-at-point)
  16     map))
  17
  18 (define-derived-mode squeeze-mode comint-mode "Squeeze"
  19   "Major mode for interacting with the Squeezebox Server CLI.\\<squeeze-mode-map>"
  20   (add-hook 'comint-preoutput-filter-functions 'url-unhex-string nil t)
  21   (add-hook 'comint-preoutput-filter-functions 'squeeze-update-state nil t))
  22
  23 (defvar squeeze-control-mode-map
  24   (let ((map (make-sparse-keymap)))
  25     (define-key map (kbd "SPC") 'squeeze-control-toggle-power)
  26     (define-key map (kbd "g") 'squeeze-control-refresh)
  27     (define-key map (kbd "+") 'squeeze-control-volume-up)
  28     (define-key map (kbd "-") 'squeeze-control-volume-down)
  29     map))
  30
  31 (define-derived-mode squeeze-control-mode special-mode "SqueezeControl"
  32   "Major mode for controlling Squeezebox Servers.\\<squeeze-control-mode-map>")
  33
  34 (defvar squeeze-control-inhibit-display nil)
  35
  36 (defun squeeze-update-state (string)
  37   (let (done-something)
  38     (dolist (line (split-string string "\n"))
  39       (when (squeeze-update-state-from-line line)
  40         (setq done-something t)))
  41     (when done-something
  42       (unless squeeze-control-inhibit-display
  43         (squeeze-control-display-players))))
  44   string)
  45
  46 (defconst squeeze-player-line-regexp
  47   "^\\(\\(?:[0-9a-f]\\{2\\}%3A\\)\\{5\\}[0-9a-f]\\{2\\}\\) ")
  48
  49 (defun squeeze-find-player (id)
  50   (dolist (player squeeze-players)
  51     (when (string= id (squeeze-player-playerid player))
  52       (return player))))
  53
  54 (defun squeeze-update-power (player state)
  55   (if state
  56       (setf (squeeze-player-power player) state)
  57     (let ((current (squeeze-player-power player)))
  58       (setf (squeeze-player-power player)
  59             (cond ((string= current "0") "1")
  60                   ((string= current "1") "0"))))))
  61
  62 (defun squeeze-update-mixer-volume (player value)
  63   (let ((current (squeeze-player-volume player))
  64         (number (string-to-number value)))
  65     (if (string-match "^[-+]" value)
  66         (setf (squeeze-player-volume player)
  67               (and current (max 0 (min 100 (+ current number)))))
  68       (setf (squeeze-player-volume player) number))))
  69
  70 (defun squeeze-update-state-from-line (string)
  71   (cond
  72    ((string-match "^players 0" string)
  73     (setq squeeze-players (squeeze-parse-players-line string))
  74     t)
  75    ((string-match squeeze-player-line-regexp string)
  76     (let ((substring (substring string (match-end 0)))
  77           (id (url-unhex-string (match-string 1 string))))
  78       (cond
  79        ((string-match "^power\\(?: \\([01]\\)\\)?" substring)
  80         (let ((state (match-string 1 substring))
  81               (player (squeeze-find-player id)))
  82           (squeeze-update-power player state))
  83         t)
  84        ((string-match "^mixer volume \\(\\(?:-\\|%2B\\)?[0-9]*\\)" substring)
  85         (let ((value (url-unhex-string (match-string 1 substring)))
  86               (player (squeeze-find-player id)))
  87           (squeeze-update-mixer-volume player value))
  88         t))))))
  89
  90 (defface squeeze-player-face
  91   '((t))
  92   "Face for displaying players"
  93   :group 'squeeze)
  94 (defface squeeze-player-on-face
  95   '((t :weight bold :inherit squeeze-player-face))
  96   "Face for displaying players which are on"
  97   :group 'squeeze)
  98 (defface squeeze-player-off-face
  99   '((t :weight light :inherit squeeze-player-face))
 100   "Face for displaying players which are off"
 101   :group 'squeeze)
 102
 103 (defface squeeze-mixer-face
 104   '((t :weight bold))
 105   "Face for displaying mixer information"
 106   :group 'squeeze)
 107 (defface squeeze-mixer-muted-face
 108   '((t :weight light :inherit squeeze-mixer-face))
 109   "Face for displaying mixer information when muted"
 110   :group 'squeeze)
 111 (defface squeeze-mixer-quiet-face
 112   '((t :foreground "green3" :inherit squeeze-mixer-face))
 113   "Face for quiet volume"
 114   :group 'squeeze)
 115 (defface squeeze-mixer-medium-face
 116   '((t :foreground "gold" :inherit squeeze-mixer-face))
 117   "Face for medium volume"
 118   :group 'squeeze)
 119 (defface squeeze-mixer-loud-face
 120   '((t :foreground "OrangeRed1" :inherit squeeze-mixer-face))
 121   "Face for loud volume"
 122   :group 'squeeze)
 123 (defface squeeze-mixer-muted-quiet-face
 124   '((t :inherit (squeeze-mixer-muted-face squeeze-mixer-quiet-face)))
 125   "Face for quiet volume when muted")
 126
 127 (defun squeeze-mixer-compute-bar (vol width)
 128   (let* ((exact (* width (/ vol 100.0)))
 129          (nfull (floor exact))
 130          (frac (- exact nfull))
 131          (nblank (floor (- width exact))))
 132     (format "%s%s%s"
 133             (make-string nfull ?█)
 134             (cond ((= width (+ nfull nblank)) "")
 135                   ((< frac 0.0625) " ")
 136                   ((< frac 0.1875) "▏")
 137                   ((< frac 0.3125) "▎")
 138                   ((< frac 0.4375) "▍")
 139                   ((< frac 0.5625) "▌")
 140                   ((< frac 0.6875) "▋")
 141                   ((< frac 0.8125) "▊")
 142                   ((< frac 0.9375) "▉")
 143                   (t "█"))
 144             (make-string nblank ? ))))
 145
 146 (defun squeeze-mixer-insert-bar (vol width)
 147   (let ((bar (squeeze-mixer-compute-bar vol width))
 148         (lo (floor (* 0.65 width)))
 149         (hi (floor (* 0.9 width))))
 150     (insert ?▕
 151             (propertize (substring bar 0 lo) 'face 'squeeze-mixer-quiet-face)
 152             (propertize (substring bar lo hi) 'face 'squeeze-mixer-medium-face)
 153             (propertize (substring bar hi) 'face 'squeeze-mixer-loud-face)
 154             ?▏
 155             )))
 156
 157 (defvar squeeze-players ())
 158
 159 (defun squeeze-control-query-players ()
 160   (interactive)
 161   (comint-send-string (get-buffer-process "*squeeze*") (format "players 0\n")))
 162
 163 (defun squeeze-control-toggle-power (&optional id)
 164   (interactive)
 165   (unless id
 166     (setq id (get-text-property (point) 'squeeze-playerid)))
 167   (comint-send-string (get-buffer-process "*squeeze*") (format "%s power\n" id)))
 168
 169 (defun squeeze-control-query-power (&optional id)
 170   (interactive)
 171   (unless id
 172     (setq id (get-text-property (point) 'squeeze-playerid)))
 173   (when id
 174     (comint-send-string (get-buffer-process "*squeeze*") (format "%s power ?\n" id))))
 175
 176 (defun squeeze-control-volume-up (&optional id inc)
 177   (interactive)
 178   (unless inc (setq inc 5))
 179   (unless id
 180     (setq id (get-text-property (point) 'squeeze-playerid)))
 181   (when id
 182     (comint-send-string (get-buffer-process "*squeeze*") (format "%s mixer volume %+d\n" id inc))))
 183
 184 (defun squeeze-control-volume-down (&optional id inc)
 185   (interactive)
 186   (unless inc (setq inc 5))
 187   (unless id
 188     (setq id (get-text-property (point) 'squeeze-playerid)))
 189   (when id
 190     (comint-send-string (get-buffer-process "*squeeze*") (format "%s mixer volume %+d\n" id (- inc)))))
 191
 192 (defun squeeze-control-query-mixer-volume (&optional id)
 193   (interactive)
 194   (unless id
 195     (setq id (get-text-property (point) 'squeeze-playerid)))
 196   (when id
 197     (comint-send-string (get-buffer-process "*squeeze*") (format "%s mixer volume ?\n" id))))
 198
 199 (defun squeeze-control-player-face (player)
 200   (let ((power (squeeze-player-power player)))
 201     (cond ((string= power "1") 'squeeze-player-on-face)
 202           ((string= power "0") 'squeeze-player-off-face)
 203           (t 'squeeze-player-face))))
 204
 205 (defun squeeze-control-listen ()
 206   (comint-send-string (get-buffer-process "*squeeze*") (format "listen 1\n")))
 207
 208 (defun squeeze-control-refresh ()
 209   (interactive)
 210   (let ((squeeze-control-inhibit-display t))
 211     (squeeze-control-query-players)
 212     (accept-process-output (get-buffer-process "*squeeze*"))
 213     (dolist (player squeeze-players)
 214       (squeeze-control-query-power (squeeze-player-playerid player))
 215       (accept-process-output (get-buffer-process "*squeeze*"))
 216       (squeeze-control-query-mixer-volume (squeeze-player-playerid player))
 217       (accept-process-output (get-buffer-process "*squeeze*"))))
 218   (squeeze-control-display-players))
 219
 220 (defun squeeze-control-display-players ()
 221   (interactive)
 222   (let ((players squeeze-players))
 223     (with-current-buffer (get-buffer-create "*squeeze-control*")
 224       (squeeze-control-mode)
 225       (read-only-mode -1)
 226       (erase-buffer)
 227       (dolist (player players)
 228         (insert (propertize (format "%20s" (squeeze-player-name player))
 229                             'face (squeeze-control-player-face player)
 230                             'squeeze-playerid (squeeze-player-playerid player)))
 231         (when (squeeze-player-volume player)
 232           (squeeze-mixer-insert-bar (squeeze-player-volume player) 28))
 233         (insert "\n"))
 234       (read-only-mode 1))))
 235
 236 (cl-defstruct (squeeze-player (:constructor squeeze-make-player))
 237   playerindex playerid uuid ip name model isplayer displaytype canpoweroff connected power volume)
 238
 239 (defun squeeze-string-plistify (string start end)
 240   (save-match-data
 241     (let (result)
 242       (loop
 243        (if (string-match "\\([a-z]+\\)%3A\\([^ \n]+\\)" string start)
 244            (let ((mend (match-end 0)))
 245              (when (> mend end)
 246                (return))
 247              (push (intern (format ":%s" (substring string (match-beginning 1) (match-end 1)))) result)
 248              (push (url-unhex-string (substring string (match-beginning 2) (match-end 2))) result)
 249              (setq start mend))
 250          (return)))
 251       (nreverse result))))
 252
 253 (defun squeeze-parse-players-line (string)
 254   (let ((countpos (string-match " count%3A\\([0-9]\\) " string))
 255         (startpos (match-end 0)))
 256     (unless countpos
 257       (message "no count found in players line"))
 258     (let ((count (parse-integer string (match-beginning 1) (match-end 1)))
 259           result endpos)
 260       (dotimes (i (1- count))
 261         (setq endpos (progn (string-match " connected%3A[0-1] " string startpos)
 262                             (match-end 0)))
 263         (push (apply 'squeeze-make-player (squeeze-string-plistify string startpos endpos)) result)
 264         (setq startpos endpos))
 265       (push (apply 'squeeze-make-player (squeeze-string-plistify string startpos (length string))) result)
 266       result)))
 267
 268 (defun squeeze-complete-command-at-point ()
 269   (save-excursion
 270     (list (progn (backward-word) (point))
 271           (progn (forward-word) (point))
 272           '(;; General commands and queries
 273             "login" "can" "version" "listen" "subscribe" "pref"
 274             "logging" "getstring" "setsncredentials" "debug"
 275             "exit" "shutdown"
 276
 277             ;; Player commands and queries
 278             "player" "count" "id" "uuid" "name" "ip" "model" "isplayer"
 279             "displaytype" "canpoweroff" "?" "signalstrength" "connected"
 280             "sleep" "sync" "syncgroups" "power" "mixer" "volume" "muting"
 281             "bass" "treble" "pitch" "show" "display" "linesperscreen"
 282             "displaynow" "playerpref" "button" "ir" "irenable"
 283             "connect" "client" "forget" "disconnect" "players"
 284
 285             ;; Database commands and queries
 286             "rescan" "rescanprogress" "abortscan" "wipecache" "info"
 287             "total" "genres" "artists" "albums" "songs" "years"
 288             "musicfolder" "playlists" "tracks" "new" "rename" "delete"
 289             "edit" "songinfo" "titles" "search" "pragma"
 290
 291             ;; Playlist commands and queries
 292             "play" "stop" "pause" "mode" "time" "genre" "artist" "album"
 293             "title" "duration" "remote" "current_title" "path" "playlist"
 294             "add" "insert" "deleteitem" "move" "delete" "preview" "resume"
 295             "save" "loadalbum" "addalbum" "loadtracks" "addtracks"
 296             "insertalbum" "deletealbum" "clear" "zap" "name" "url"
 297             "modified" "playlistsinfo" "index" "shuffle" "repeat"
 298             "playlistcontrol"
 299
 300             ;; Compound queries
 301             "serverstatus" "status" "displaystatus" "readdirectory"
 302
 303             ;; Notifications
 304
 305             ;; Alarm commands and queries
 306             "alarm" "alarms"
 307
 308             ;; Plugins commands and queries
 309             "favorites"
 310             ))))
 311
 312 (defun squeeze ()
 313   (interactive)
 314   (let ((buffer (make-comint-in-buffer "squeeze" nil
 315                                        (cons squeeze-server-address
 316                                              squeeze-server-port))))
 317     (switch-to-buffer buffer)
 318     (squeeze-mode)))
 319
 320 (defun squeeze-control ()
 321   (interactive)
 322   (squeeze)
 323   (let ((buffer (get-buffer-create "*squeeze-control*")))
 324     (switch-to-buffer buffer)
 325     (squeeze-control-listen)
 326     (squeeze-control-refresh)
 327     (squeeze-control-display-players)))