src/specializable.lisp

   1 ;;; written by David Lichteblau, based on code by Christophe Rhodes,
   2 ;;; Closette, and SBCL
   3 ;;;
   4 ;;; http://www.lichteblau.com/git/?p=specializable.git;a=blob_plain;f=specializable.lisp;hb=eb30d235951c3c1d128811278760f1db36cd336c
   5
   6 (defpackage "SPECIALIZABLE"
   7   (:use "CL" "SB-EXT")
   8   (:export "SPECIALIZABLE-GENERIC-FUNCTION" "SPECIALIZABLE-METHOD"
   9            "EXTENDED-SPECIALIZER"
  10
  11            "SPECIALIZER-ACCEPTS-P" "SPECIALIZER-ACCEPTS-GENERALIZER-P"
  12            "SPECIALIZER<"
  13
  14            "GENERALIZER-OF-USING-CLASS"
  15            "COMPUTE-APPLICABLE-METHODS-USING-GENERALIZERS"
  16            "GENERALIZER-EQUAL-HASH-KEY"
  17
  18            "DEFINE-EXTENDED-SPECIALIZER"))
  19
  20 (in-package "SPECIALIZABLE")
  21
  22 (defclass extended-specializer (sb-mop:specializer)
  23   ;; FIXME: this doesn't actually do quite what I wanted.
  24   ((direct-methods-table :allocation :class
  25                          :initform nil :accessor direct-methods-table)))
  26
  27 (defmethod sb-mop:add-direct-method ((specializer extended-specializer) method)
  28   (let* ((table (direct-methods-table specializer))
  29          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  30     (unless cell
  31       (setf cell (cons specializer nil))
  32       (push cell (direct-methods-table specializer)))
  33     (push method (cdr cell))))
  34
  35 (defmethod sb-mop:remove-direct-method ((specializer extended-specializer) method)
  36   (let* ((table (direct-methods-table specializer))
  37          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  38     (setf (cdr cell) (remove method (cdr cell)))))
  39
  40 (defmethod sb-mop:specializer-direct-methods ((specializer extended-specializer))
  41   (cdr (assoc specializer (direct-methods-table specializer)
  42               :test #'sb-pcl::same-specializer-p)))
  43 (defmethod sb-mop:specializer-direct-generic-functions ((specializer extended-specializer))
  44   (remove-duplicates (mapcar #'sb-mop:method-generic-function (sb-mop:specializer-direct-methods specializer))))
  45
  46 (defclass specializable-generic-function (standard-generic-function)
  47   ((emf-table :initform (make-hash-table :test 'equal) :reader emf-table)
  48    (cacheingp :initform t :initarg :cacheingp)
  49    (single-arg-cacheing-p :initform t :initarg :single-arg-cacheing-p))
  50   (:metaclass sb-mop:funcallable-standard-class)
  51   (:default-initargs :method-class (find-class 'specializable-method)))
  52
  53 ;;; TODO: we don't use this class yet, but we might do later
  54 (defclass specializable-method (standard-method) ())
  55
  56 ;;; TODO use info?
  57 (defun extended-specializer-name-p (name)
  58   (and (symbolp name)
  59        (get name 'extended-specializer-parser)))
  60
  61 (deftype extended-specializer-name ()
  62   `(satisfies extended-specializer-name-p))
  63
  64 (defmacro define-extended-specializer (name (gf-var &rest args) &body body)
  65   ;; FIXME: unparser
  66   `(setf (get ',name 'extended-specializer-parser)
  67          (lambda (,gf-var ,@args)
  68            ,@body)))
  69
  70 ;; doesn't work, because we'd have to dump GF into the fasl for the macro
  71 ;; expansion
  72 ;;; (defun intern-extended-specializer (gf sname)
  73 ;;;   (destructuring-bind (kind &rest args) sname
  74 ;;;     (setf (gethash sname (generic-function-extended-specializers gf))
  75 ;;;       (apply (or (get kind 'extended-specializer-parser)
  76 ;;;                  (error "not declared as an extended specializer name: ~A"
  77 ;;;                         kind))
  78 ;;;              gf
  79 ;;;              args))))
  80
  81 (defun make-extended-specializer (sname)
  82   (destructuring-bind (kind &rest args) sname
  83     (apply (or (get kind 'extended-specializer-parser)
  84                (error "not declared as an extended specializer name: ~A"
  85                       kind))
  86            '|This is not a generic function| ;fixme, see comment above
  87            args)))
  88
  89 ;;; from SBCL:
  90
  91 (defmethod sb-pcl:parse-specializer-using-class
  92     ((gf specializable-generic-function) (specializer-name t))
  93   (if (typep specializer-name '(cons extended-specializer-name))
  94       (make-extended-specializer specializer-name)
  95       (call-next-method)))
  96
  97 (defmethod sb-pcl:make-method-specializers-form
  98     ((gf specializable-generic-function) method snames env)
  99   (declare (ignore method env))
 100   (flet ((parse (name)
 101            (cond
 102              ((typep name 'sb-mop:specializer) name)
 103              ((symbolp name) `(find-class ',name))
 104              ((consp name)
 105               (case (car name)
 106                 (eql `(sb-mop:intern-eql-specializer ,(cadr name)))
 107                 (t `(make-extended-specializer ',name))))
 108              (t (error "unexpected specializer name")))))
 109     `(list ,@(mapcar #'parse snames))))
 110
 111 ;;; from Closette, changed to use some SBCL functions:
 112
 113 ;;; FIXME: this is not actually sufficient argument checking
 114 (defun required-portion (gf args)
 115   (let ((number-required
 116          (sb-pcl::arg-info-number-required (sb-pcl::gf-arg-info gf))))
 117     (when (< (length args) number-required)
 118       (error "Too few arguments to generic function ~S." gf))
 119     (subseq args 0 number-required)))
 120
 121 (defgeneric generalizer-equal-hash-key (generic-function generalizer))
 122 (defmethod generalizer-equal-hash-key
 123     ((gf specializable-generic-function) (g class))
 124   (sb-pcl::class-wrapper g))
 125
 126 (defun first-arg-only-special-case (gf)
 127   (let ((arg-info (sb-pcl::gf-arg-info gf)))
 128     (and (slot-value gf 'single-arg-cacheing-p)
 129          (>= (sb-pcl::arg-info-number-required arg-info) 1)
 130          (every (lambda (x) (eql x t))
 131                 (cdr (sb-pcl::arg-info-metatypes arg-info))))))
 132
 133 ;;; FIXME: in some kind of order, the discriminating function needs to handle:
 134 ;;; - argument count checking;
 135 ;;; - DONE (in effective method) keyword argument validity;
 136 ;;; - DONE flushing the emf cache on method addition/removal
 137 ;;; - DONE (sort of, using wrappers/g-e-h-k) flushing the cache on class redefinition;
 138 ;;; - cache thread-safety.
 139 ;;; - speed
 140 ;;; - DONE (in SBCL itself) interaction with TRACE et al.
 141 (defmethod sb-mop:compute-discriminating-function ((gf specializable-generic-function))
 142   (cond
 143     ((not (slot-value gf 'cacheingp))
 144      (lambda (&rest args)
 145        (let ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 146                                    args)))
 147          (slow-method-lookup-and-call gf args generalizers))))
 148     ((first-arg-only-special-case gf)
 149      (lambda (&rest args)
 150        (let* ((g (generalizer-of-using-class gf (car args)))
 151               (k (generalizer-equal-hash-key gf g))
 152               (emfun (gethash k (emf-table gf) nil)))
 153          (if emfun
 154              (sb-pcl::invoke-emf emfun args)
 155              (slow-method-lookup-and-call
 156               gf args (cons g (mapcar (lambda (x) (generalizer-of-using-class gf x))
 157                                       (cdr (required-portion gf args)))))))))
 158     (t
 159      (lambda (&rest args)
 160        (let* ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 161                                     (required-portion gf args)))
 162               (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers))
 163               (emfun (gethash keys (emf-table gf) nil)))
 164          (if emfun
 165              (sb-pcl::invoke-emf emfun args)
 166              (slow-method-lookup-and-call gf args generalizers)))))))
 167
 168 (defmethod reinitialize-instance :after ((gf specializable-generic-function) &key)
 169   (clrhash (emf-table gf)))
 170
 171 (defun slow-method-lookup (gf args generalizers)
 172   (multiple-value-bind (applicable-methods definitivep)
 173       (compute-applicable-methods-using-generalizers gf generalizers)
 174     (unless definitivep
 175       (setf applicable-methods (compute-applicable-methods gf args)))
 176     (values (compute-effective-method-function gf applicable-methods)
 177             definitivep)))
 178
 179 (defun slow-method-lookup-and-call (gf args generalizers)
 180   (multiple-value-bind (emf cacheablep)
 181       (slow-method-lookup gf args generalizers)
 182     (when cacheablep
 183       (let ((keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers)))
 184         (if (first-arg-only-special-case gf)
 185             (setf (gethash (car keys) (emf-table gf)) emf)
 186             (setf (gethash keys (emf-table gf)) emf))))
 187     (sb-pcl::invoke-emf emf args)))
 188
 189 (defun compute-effective-method-function (gf methods)
 190   (if (null methods)
 191       (lambda (&rest args) (apply #'no-applicable-method gf args))
 192       (let* ((mc (sb-mop:generic-function-method-combination gf))
 193              (sb-pcl::*applicable-methods* methods)
 194              (em (sb-mop:compute-effective-method gf mc methods)))
 195         (sb-pcl::make-effective-method-function gf em))))
 196
 197 ;; new, not in closette
 198 (defgeneric generalizer-of-using-class (generic-function object))
 199 (defmethod generalizer-of-using-class ((generic-function specializable-generic-function) object)
 200   (class-of object))
 201
 202 (defgeneric specializer-accepts-generalizer-p (gf specializer generalizer))
 203 (defmethod specializer-accepts-generalizer-p
 204     ((gf specializable-generic-function) (specializer class) (generalizer class))
 205   (if (subtypep generalizer specializer)
 206       (values t t)
 207       (values nil t)))
 208 (defmethod specializer-accepts-generalizer-p
 209     ((gf specializable-generic-function) (specializer sb-mop:eql-specializer) (generalizer class))
 210   (if (eq generalizer (class-of (sb-mop:eql-specializer-object specializer)))
 211       (values t nil)
 212       (values nil t)))
 213
 214 (defgeneric compute-applicable-methods-using-generalizers (gf generalizers))
 215 (defmethod compute-applicable-methods-using-generalizers
 216     ((gf specializable-generic-function) generalizers)
 217   ;; differs from closette
 218   (let ((result-definitive-p t))
 219     (flet ((filter (method)
 220              (every (lambda (s g)
 221                       (multiple-value-bind (acceptsp definitivep)
 222                           (specializer-accepts-generalizer-p gf s g)
 223                         (unless definitivep
 224                           (setf result-definitive-p nil))
 225                         acceptsp))
 226                     (sb-mop:method-specializers method) generalizers))
 227            (sorter (m1 m2)
 228              (method-more-specific-p gf m1 m2 generalizers)))
 229       (values
 230        (sort
 231         (copy-list (remove-if-not #'filter (sb-mop:generic-function-methods gf)))
 232         #'sorter)
 233        result-definitive-p))))
 234
 235 ;; new, not in closette
 236 (defgeneric specializer-accepts-p (specializer object))
 237 (defmethod specializer-accepts-p ((specializer class) object)
 238   (typep object specializer))
 239 (defmethod specializer-accepts-p ((specializer sb-mop:eql-specializer) object)
 240   (eq object (sb-mop:eql-specializer-object specializer)))
 241
 242 (defmethod compute-applicable-methods
 243     ((gf specializable-generic-function) arguments)
 244   ;; new, not in closette
 245   (sort
 246    (copy-list
 247     (remove-if-not #'(lambda (method)
 248                        (every #'specializer-accepts-p
 249                               (sb-mop:method-specializers method)
 250                               arguments))
 251                    (sb-mop:generic-function-methods gf)))
 252    (let ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 253                                (required-portion gf arguments))))
 254      (lambda (m1 m2)
 255        (method-more-specific-p gf m1 m2 generalizers)))))
 256
 257 (defun method-more-specific-p (gf method1 method2 generalizers)
 258   ;; FIXME: argument precedence order
 259   (block nil
 260     (mapc #'(lambda (spec1 spec2 generalizer)
 261               (ecase (specializer< gf spec1 spec2 generalizer)
 262                 (< (return t))
 263                 (=)
 264                 ((nil > /=) (return nil))))
 265           (sb-mop:method-specializers method1)
 266           (sb-mop:method-specializers method2)
 267           generalizers)
 268     nil))
 269
 270 ;; new, not in closette
 271 (defgeneric specializer< (gf s1 s2 generalizer))
 272 (defmethod specializer<
 273     ((gf specializable-generic-function) (s1 class) (s2 class) (generalizer class))
 274   (if (eq s1 s2)
 275       '=
 276       (let ((cpl (sb-mop:class-precedence-list generalizer)))
 277         (if (find s2 (cdr (member s1 cpl)))
 278             '<
 279             '>))))
 280 (defmethod specializer<
 281     ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 sb-mop:eql-specializer) generalizer)
 282   (declare (ignore generalizer))
 283   (if (eq (sb-mop:eql-specializer-object s1) (sb-mop:eql-specializer-object s2))
 284       '=
 285       nil))
 286 (defmethod specializer< ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 class) generalizer)
 287   (declare (ignore generalizer))
 288   '<)
 289 (defmethod specializer< ((gf specializable-generic-function) (c1 class) (c2 sb-mop:eql-specializer) generalizer)
 290   (declare (ignore generalizer))
 291   '>)