src/specializable.lisp

   1 ;;; written by David Lichteblau, based on code by Christophe Rhodes,
   2 ;;; Closette, and SBCL
   3 ;;;
   4 ;;; http://www.lichteblau.com/git/?p=specializable.git;a=blob_plain;f=specializable.lisp;hb=eb30d235951c3c1d128811278760f1db36cd336c
   5
   6 (defpackage "SPECIALIZABLE"
   7   (:use "CL" "SB-EXT")
   8   (:export "SPECIALIZABLE-GENERIC-FUNCTION" "SPECIALIZABLE-METHOD"
   9            "EXTENDED-SPECIALIZER"
  10
  11            "SPECIALIZER-ACCEPTS-P" "SPECIALIZER-ACCEPTS-GENERALIZER-P"
  12            "SPECIALIZER<"
  13
  14            "GENERALIZERS-OF-USING-CLASS"
  15            "GENERALIZER-OF-USING-CLASS"
  16            "COMPUTE-APPLICABLE-METHODS-USING-GENERALIZERS"
  17            "GENERALIZER-EQUAL-HASH-KEY"
  18
  19            "DEFINE-EXTENDED-SPECIALIZER"))
  20
  21 (in-package "SPECIALIZABLE")
  22
  23 (defclass extended-specializer (sb-mop:specializer)
  24   ;; FIXME: this doesn't actually do quite what I wanted.
  25   ((direct-methods-table :allocation :class
  26                          :initform nil :accessor direct-methods-table)))
  27
  28 (defmethod sb-mop:add-direct-method ((specializer extended-specializer) method)
  29   (let* ((table (direct-methods-table specializer))
  30          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  31     (unless cell
  32       (setf cell (cons specializer nil))
  33       (push cell (direct-methods-table specializer)))
  34     (push method (cdr cell))))
  35
  36 (defmethod sb-mop:remove-direct-method ((specializer extended-specializer) method)
  37   (let* ((table (direct-methods-table specializer))
  38          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  39     (setf (cdr cell) (remove method (cdr cell)))))
  40
  41 (defmethod sb-mop:specializer-direct-methods ((specializer extended-specializer))
  42   (cdr (assoc specializer (direct-methods-table specializer)
  43               :test #'sb-pcl::same-specializer-p)))
  44 (defmethod sb-mop:specializer-direct-generic-functions ((specializer extended-specializer))
  45   (remove-duplicates (mapcar #'sb-mop:method-generic-function (sb-mop:specializer-direct-methods specializer))))
  46
  47 (defclass specializable-generic-function (standard-generic-function)
  48   ((emf-table :initform (make-hash-table :test 'equal) :reader emf-table)
  49    (cacheingp :initform t :initarg :cacheingp)
  50    (single-arg-cacheing-p :initform t :initarg :single-arg-cacheing-p))
  51   (:metaclass sb-mop:funcallable-standard-class)
  52   (:default-initargs :method-class (find-class 'specializable-method)))
  53
  54 ;;; TODO: we don't use this class yet, but we might do later
  55 (defclass specializable-method (standard-method) ())
  56
  57 ;;; TODO use info?
  58 (defun extended-specializer-name-p (name)
  59   (and (symbolp name)
  60        (get name 'extended-specializer-parser)))
  61
  62 (deftype extended-specializer-name ()
  63   `(satisfies extended-specializer-name-p))
  64
  65 (defmacro define-extended-specializer (name (gf-var &rest args) &body body)
  66   ;; FIXME: unparser
  67   `(setf (get ',name 'extended-specializer-parser)
  68          (lambda (,gf-var ,@args)
  69            ,@body)))
  70
  71 ;; doesn't work, because we'd have to dump GF into the fasl for the macro
  72 ;; expansion
  73 ;;; (defun intern-extended-specializer (gf sname)
  74 ;;;   (destructuring-bind (kind &rest args) sname
  75 ;;;     (setf (gethash sname (generic-function-extended-specializers gf))
  76 ;;;       (apply (or (get kind 'extended-specializer-parser)
  77 ;;;                  (error "not declared as an extended specializer name: ~A"
  78 ;;;                         kind))
  79 ;;;              gf
  80 ;;;              args))))
  81
  82 (defun make-extended-specializer (sname)
  83   (destructuring-bind (kind &rest args) sname
  84     (apply (or (get kind 'extended-specializer-parser)
  85                (error "not declared as an extended specializer name: ~A"
  86                       kind))
  87            '|This is not a generic function| ;fixme, see comment above
  88            args)))
  89
  90 ;;; from SBCL:
  91
  92 (defmethod sb-pcl:parse-specializer-using-class
  93     ((gf specializable-generic-function) (specializer-name t))
  94   (if (typep specializer-name '(cons extended-specializer-name))
  95       (make-extended-specializer specializer-name)
  96       (call-next-method)))
  97
  98 (defmethod sb-pcl:make-method-specializers-form
  99     ((gf specializable-generic-function) method snames env)
 100   (declare (ignore method env))
 101   (flet ((parse (name)
 102            (cond
 103              ((typep name 'sb-mop:specializer) name)
 104              ((symbolp name) `(find-class ',name))
 105              ((consp name)
 106               (case (car name)
 107                 (eql `(sb-mop:intern-eql-specializer ,(cadr name)))
 108                 (t `(make-extended-specializer ',name))))
 109              (t (error "unexpected specializer name")))))
 110     `(list ,@(mapcar #'parse snames))))
 111
 112 ;;; from Closette, changed to use some SBCL functions:
 113
 114 (defgeneric generalizer-equal-hash-key (generic-function generalizer))
 115 (defmethod generalizer-equal-hash-key
 116     ((gf specializable-generic-function) (g class))
 117   (sb-pcl::class-wrapper g))
 118
 119 (defgeneric generalizer-args (generic-function generalizer))  ; TODO add a subclass of specializable generic-function for this?
 120 (defmethod generalizer-args ((generic-function specializable-generic-function)
 121                              (generalizer t))
 122   '())
 123
 124 (defun first-arg-only-special-case (gf)
 125   (let ((arg-info (sb-pcl::gf-arg-info gf)))
 126     (and (slot-value gf 'single-arg-cacheing-p)
 127          (>= (sb-pcl::arg-info-number-required arg-info) 1)
 128          (every (lambda (x) (eql x t))
 129                 (cdr (sb-pcl::arg-info-metatypes arg-info))))))
 130
 131 ;;; FIXME: in some kind of order, the discriminating function needs to handle:
 132 ;;; - argument count checking;
 133 ;;; - DONE (in effective method) keyword argument validity;
 134 ;;; - DONE flushing the emf cache on method addition/removal
 135 ;;; - DONE (sort of, using wrappers/g-e-h-k) flushing the cache on class redefinition;
 136 ;;; - cache thread-safety.
 137 ;;; - speed
 138 ;;; - DONE (in SBCL itself) interaction with TRACE et al.
 139 (defmethod sb-mop:compute-discriminating-function ((gf specializable-generic-function))
 140   (cond
 141     ((not (slot-value gf 'cacheingp))
 142      (lambda (&rest args)
 143        (let ((generalizers (generalizers-of-using-class gf args)))
 144          (slow-method-lookup-and-call gf args generalizers))))
 145     ((first-arg-only-special-case gf)
 146      (lambda (&rest args)
 147        (let* ((generalizer (generalizer-of-using-class gf (first args)))
 148               (key (generalizer-equal-hash-key gf generalizer))
 149               (extra-args (generalizer-args gf generalizer))
 150               (emfun (gethash key (emf-table gf) nil)))
 151          (if emfun
 152              (sb-pcl::invoke-emf emfun (append args extra-args)) ; TODO conses
 153              (slow-method-lookup-and-call
 154               gf (append args extra-args)
 155               (list* generalizer
 156                      (mapcar (lambda (x) (generalizer-of-using-class gf x))
 157                              (rest (required-portion gf args)))))))))
 158     (t
 159      (lambda (&rest args)
 160        (let* ((generalizers (generalizers-of-using-class gf args))
 161               (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers))
 162               (extra-args (mapcan (lambda (x) (generalizer-args gf x)) generalizers)) ; TODO destructive?
 163               (emfun (gethash keys (emf-table gf) nil)))
 164          (if emfun
 165              (sb-pcl::invoke-emf emfun (append args extra-args)) ; TODO conses
 166              (slow-method-lookup-and-call
 167               gf (append args extra-args)
 168               generalizers)))))))
 169
 170 (defmethod reinitialize-instance :after ((gf specializable-generic-function) &key)
 171   (clrhash (emf-table gf)))
 172
 173 (defun slow-method-lookup (gf args generalizers)
 174   (multiple-value-bind (applicable-methods definitivep)
 175       (compute-applicable-methods-using-generalizers gf generalizers)
 176     (unless definitivep
 177       (setf applicable-methods (compute-applicable-methods gf args)))
 178     (values (compute-effective-method-function gf applicable-methods)
 179             definitivep)))
 180
 181 (defun slow-method-lookup-and-call (gf args generalizers)
 182   (multiple-value-bind (emf cacheablep)
 183       (slow-method-lookup gf args generalizers)
 184     (when cacheablep
 185       (let ((keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers)))
 186         (if (first-arg-only-special-case gf)
 187             (setf (gethash (car keys) (emf-table gf)) emf)
 188             (setf (gethash keys (emf-table gf)) emf))))
 189     (sb-pcl::invoke-emf emf args)))
 190
 191 (defun compute-effective-method-function (gf methods)
 192   (if (null methods)
 193       (lambda (&rest args) (apply #'no-applicable-method gf args))
 194       (let* ((mc (sb-mop:generic-function-method-combination gf))
 195              (sb-pcl::*applicable-methods* methods)
 196              (em (sb-mop:compute-effective-method gf mc methods)))
 197         (sb-pcl::make-effective-method-function gf em))))
 198
 199 ;; new, not in closette
 200   ;;; FIXME: this is not actually sufficient argument checking
 201 (defun required-portion (gf args)
 202   (let ((number-required
 203           (sb-pcl::arg-info-number-required (sb-pcl::gf-arg-info gf))))
 204     (when (< (length args) number-required)
 205       (error "Too few arguments to generic function ~S." gf))
 206     (subseq args 0 number-required)))
 207
 208 (defgeneric generalizers-of-using-class (generic-function args))
 209
 210 (defmethod generalizers-of-using-class ((generic-function specializable-generic-function) args)
 211   (mapcar (lambda (arg) (generalizer-of-using-class generic-function arg))
 212           (required-portion generic-function args)))
 213
 214 (defgeneric generalizer-of-using-class (generic-function object))
 215 (defmethod generalizer-of-using-class ((generic-function specializable-generic-function) object)
 216   (class-of object))
 217
 218 (defgeneric specializer-accepts-generalizer-p (gf specializer generalizer))
 219 (defmethod specializer-accepts-generalizer-p
 220     ((gf specializable-generic-function) (specializer class) (generalizer class))
 221   (if (subtypep generalizer specializer)
 222       (values t t)
 223       (values nil t)))
 224 (defmethod specializer-accepts-generalizer-p
 225     ((gf specializable-generic-function) (specializer sb-mop:eql-specializer) (generalizer class))
 226   (if (eq generalizer (class-of (sb-mop:eql-specializer-object specializer)))
 227       (values t nil)
 228       (values nil t)))
 229
 230 (defgeneric compute-applicable-methods-using-generalizers (gf generalizers))
 231 (defmethod compute-applicable-methods-using-generalizers
 232     ((gf specializable-generic-function) generalizers)
 233   ;; differs from closette
 234   (let ((result-definitive-p t))
 235     (flet ((filter (method)
 236              (every (lambda (s g)
 237                       (multiple-value-bind (acceptsp definitivep)
 238                           (specializer-accepts-generalizer-p gf s g)
 239                         (unless definitivep
 240                           (setf result-definitive-p nil))
 241                         acceptsp))
 242                     (sb-mop:method-specializers method) generalizers))
 243            (sorter (m1 m2)
 244              (method-more-specific-p gf m1 m2 generalizers)))
 245       (values
 246        (sort
 247         (copy-list (remove-if-not #'filter (sb-mop:generic-function-methods gf)))
 248         #'sorter)
 249        result-definitive-p))))
 250
 251 ;; new, not in closette
 252 (defgeneric specializer-accepts-p (specializer object))
 253 (defmethod specializer-accepts-p ((specializer class) object)
 254   (typep object specializer))
 255 (defmethod specializer-accepts-p ((specializer sb-mop:eql-specializer) object)
 256   (eq object (sb-mop:eql-specializer-object specializer)))
 257
 258 (defmethod compute-applicable-methods
 259     ((gf specializable-generic-function) arguments)
 260   ;; new, not in closette
 261   (sort
 262    (copy-list
 263     (remove-if-not #'(lambda (method)
 264                        (every #'specializer-accepts-p
 265                               (sb-mop:method-specializers method)
 266                               arguments))
 267                    (sb-mop:generic-function-methods gf)))
 268    (let ((generalizers (generalizers-of-using-class gf arguments)))
 269      (lambda (m1 m2)
 270        (method-more-specific-p gf m1 m2 generalizers)))))
 271
 272 (defun method-more-specific-p (gf method1 method2 generalizers)
 273   ;; FIXME: argument precedence order
 274   (block nil
 275     (mapc #'(lambda (spec1 spec2 generalizer)
 276               (ecase (specializer< gf spec1 spec2 generalizer)
 277                 (< (return t))
 278                 (=)
 279                 ((nil > /=) (return nil))))
 280           (sb-mop:method-specializers method1)
 281           (sb-mop:method-specializers method2)
 282           generalizers)
 283     nil))
 284
 285 ;; new, not in closette
 286 (defgeneric specializer< (gf s1 s2 generalizer))
 287 (defmethod specializer<
 288     ((gf specializable-generic-function) (s1 class) (s2 class) (generalizer class))
 289   (if (eq s1 s2)
 290       '=
 291       (let ((cpl (sb-mop:class-precedence-list generalizer)))
 292         (if (find s2 (cdr (member s1 cpl)))
 293             '<
 294             '>))))
 295 (defmethod specializer<
 296     ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 sb-mop:eql-specializer) generalizer)
 297   (declare (ignore generalizer))
 298   (if (eq (sb-mop:eql-specializer-object s1) (sb-mop:eql-specializer-object s2))
 299       '=
 300       nil))
 301 (defmethod specializer< ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 class) generalizer)
 302   (declare (ignore generalizer))
 303   '<)
 304 (defmethod specializer< ((gf specializable-generic-function) (c1 class) (c2 sb-mop:eql-specializer) generalizer)
 305   (declare (ignore generalizer))
 306   '>)