src/specializable.lisp

   1 ;;; written by David Lichteblau, based on code by Christophe Rhodes,
   2 ;;; Closette, and SBCL
   3 ;;;
   4 ;;; http://www.lichteblau.com/git/?p=specializable.git;a=blob_plain;f=specializable.lisp;hb=eb30d235951c3c1d128811278760f1db36cd336c
   5
   6 (defpackage "SPECIALIZABLE"
   7   (:use "CL" "SB-EXT")
   8   (:export "SPECIALIZABLE-GENERIC-FUNCTION" "SPECIALIZABLE-METHOD"
   9            "EXTENDED-SPECIALIZER"
  10
  11            "SPECIALIZER-ACCEPTS-P" "SPECIALIZER-ACCEPTS-GENERALIZER-P"
  12            "SPECIALIZER<"
  13
  14            "GENERALIZERS-OF-USING-CLASS"
  15            "GENERALIZER-OF-USING-CLASS"
  16            "COMPUTE-APPLICABLE-METHODS-USING-GENERALIZERS"
  17            "GENERALIZER-EQUAL-HASH-KEY"
  18
  19            "DEFINE-EXTENDED-SPECIALIZER"))
  20
  21 (in-package "SPECIALIZABLE")
  22
  23 (defclass extended-specializer (sb-mop:specializer)
  24   ;; FIXME: this doesn't actually do quite what I wanted.
  25   ((direct-methods-table :allocation :class
  26                          :initform nil :accessor direct-methods-table)))
  27
  28 (defmethod sb-mop:add-direct-method ((specializer extended-specializer) method)
  29   (let* ((table (direct-methods-table specializer))
  30          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  31     (unless cell
  32       (setf cell (cons specializer nil))
  33       (push cell (direct-methods-table specializer)))
  34     (push method (cdr cell))))
  35
  36 (defmethod sb-mop:remove-direct-method ((specializer extended-specializer) method)
  37   (let* ((table (direct-methods-table specializer))
  38          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  39     (setf (cdr cell) (remove method (cdr cell)))))
  40
  41 (defmethod sb-mop:specializer-direct-methods ((specializer extended-specializer))
  42   (cdr (assoc specializer (direct-methods-table specializer)
  43               :test #'sb-pcl::same-specializer-p)))
  44 (defmethod sb-mop:specializer-direct-generic-functions ((specializer extended-specializer))
  45   (remove-duplicates (mapcar #'sb-mop:method-generic-function (sb-mop:specializer-direct-methods specializer))))
  46
  47 (defclass specializable-generic-function (standard-generic-function)
  48   ((emf-table :initform (make-hash-table :test 'equal) :reader emf-table)
  49    (cacheingp :initform t :initarg :cacheingp)
  50    (single-arg-cacheing-p :initform t :initarg :single-arg-cacheing-p))
  51   (:metaclass sb-mop:funcallable-standard-class)
  52   (:default-initargs :method-class (find-class 'specializable-method)))
  53
  54 ;;; TODO: we don't use this class yet, but we might do later
  55 (defclass specializable-method (standard-method) ())
  56
  57 ;;; TODO use info?
  58 (defun extended-specializer-name-p (name)
  59   (and (symbolp name)
  60        (get name 'extended-specializer-parser)))
  61
  62 (deftype extended-specializer-name ()
  63   `(satisfies extended-specializer-name-p))
  64
  65 (defmacro define-extended-specializer (name (gf-var &rest args) &body body)
  66   ;; FIXME: unparser
  67   `(setf (get ',name 'extended-specializer-parser)
  68          (lambda (,gf-var ,@args)
  69            ,@body)))
  70
  71 ;; doesn't work, because we'd have to dump GF into the fasl for the macro
  72 ;; expansion
  73 ;;; (defun intern-extended-specializer (gf sname)
  74 ;;;   (destructuring-bind (kind &rest args) sname
  75 ;;;     (setf (gethash sname (generic-function-extended-specializers gf))
  76 ;;;       (apply (or (get kind 'extended-specializer-parser)
  77 ;;;                  (error "not declared as an extended specializer name: ~A"
  78 ;;;                         kind))
  79 ;;;              gf
  80 ;;;              args))))
  81
  82 (defun make-extended-specializer (sname)
  83   (destructuring-bind (kind &rest args) sname
  84     (apply (or (get kind 'extended-specializer-parser)
  85                (error "not declared as an extended specializer name: ~A"
  86                       kind))
  87            '|This is not a generic function| ;fixme, see comment above
  88            args)))
  89
  90 ;;; from SBCL:
  91
  92 (defmethod sb-pcl:parse-specializer-using-class
  93     ((gf specializable-generic-function) (specializer-name t))
  94   (if (typep specializer-name '(cons extended-specializer-name))
  95       (make-extended-specializer specializer-name)
  96       (call-next-method)))
  97
  98 (defmethod sb-pcl:make-method-specializers-form
  99     ((gf specializable-generic-function) method snames env)
 100   (declare (ignore method env))
 101   (flet ((parse (name)
 102            (cond
 103              ((typep name 'sb-mop:specializer) name)
 104              ((symbolp name) `(find-class ',name))
 105              ((consp name)
 106               (case (car name)
 107                 (eql `(sb-mop:intern-eql-specializer ,(cadr name)))
 108                 (t `(make-extended-specializer ',name))))
 109              (t (error "unexpected specializer name")))))
 110     `(list ,@(mapcar #'parse snames))))
 111
 112 ;;; from Closette, changed to use some SBCL functions:
 113
 114 (defgeneric generalizer-equal-hash-key (generic-function generalizer))
 115 (defmethod generalizer-equal-hash-key
 116     ((gf specializable-generic-function) (g class))
 117   (sb-pcl::class-wrapper g))
 118
 119 (defun first-arg-only-special-case (gf)
 120   (let ((arg-info (sb-pcl::gf-arg-info gf)))
 121     (and (slot-value gf 'single-arg-cacheing-p)
 122          (>= (sb-pcl::arg-info-number-required arg-info) 1)
 123          (every (lambda (x) (eql x t))
 124                 (cdr (sb-pcl::arg-info-metatypes arg-info))))))
 125
 126 ;;; FIXME: in some kind of order, the discriminating function needs to handle:
 127 ;;; - argument count checking;
 128 ;;; - DONE (in effective method) keyword argument validity;
 129 ;;; - DONE flushing the emf cache on method addition/removal
 130 ;;; - DONE (sort of, using wrappers/g-e-h-k) flushing the cache on class redefinition;
 131 ;;; - cache thread-safety.
 132 ;;; - speed
 133 ;;; - DONE (in SBCL itself) interaction with TRACE et al.
 134 (defmethod sb-mop:compute-discriminating-function ((gf specializable-generic-function))
 135   (cond
 136     ((not (slot-value gf 'cacheingp))
 137      (lambda (&rest args)
 138        (let ((generalizers (generalizers-of-using-class gf args)))
 139          (slow-method-lookup-and-call gf args generalizers))))
 140     ((first-arg-only-special-case gf)
 141      (lambda (&rest args)
 142        (let* ((generalizer (first (generalizers-of-using-class gf args))) ; TODO defeats purpose of special case
 143               (key (generalizer-equal-hash-key gf generalizer))
 144               (emfun (gethash key (emf-table gf) nil)))
 145          (if emfun
 146              (sb-pcl::invoke-emf emfun args)
 147              (slow-method-lookup-and-call
 148               gf args (list* generalizer
 149                              (mapcar (lambda (x) (generalizer-of-using-class gf x))
 150                                      (rest (required-portion gf args)))))))))
 151     (t
 152      (lambda (&rest args)
 153        (let* ((generalizers (generalizers-of-using-class gf args))
 154               (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers))
 155               (emfun (gethash keys (emf-table gf) nil)))
 156          (if emfun
 157              (sb-pcl::invoke-emf emfun args)
 158              (slow-method-lookup-and-call gf args generalizers)))))))
 159
 160 (defmethod reinitialize-instance :after ((gf specializable-generic-function) &key)
 161   (clrhash (emf-table gf)))
 162
 163 (defun slow-method-lookup (gf args generalizers)
 164   (multiple-value-bind (applicable-methods definitivep)
 165       (compute-applicable-methods-using-generalizers gf generalizers)
 166     (unless definitivep
 167       (setf applicable-methods (compute-applicable-methods gf args)))
 168     (values (compute-effective-method-function gf applicable-methods)
 169             definitivep)))
 170
 171 (defun slow-method-lookup-and-call (gf args generalizers)
 172   (multiple-value-bind (emf cacheablep)
 173       (slow-method-lookup gf args generalizers)
 174     (when cacheablep
 175       (let ((keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers)))
 176         (if (first-arg-only-special-case gf)
 177             (setf (gethash (car keys) (emf-table gf)) emf)
 178             (setf (gethash keys (emf-table gf)) emf))))
 179     (sb-pcl::invoke-emf emf args)))
 180
 181 (defun compute-effective-method-function (gf methods)
 182   (if (null methods)
 183       (lambda (&rest args) (apply #'no-applicable-method gf args))
 184       (let* ((mc (sb-mop:generic-function-method-combination gf))
 185              (sb-pcl::*applicable-methods* methods)
 186              (em (sb-mop:compute-effective-method gf mc methods)))
 187         (sb-pcl::make-effective-method-function gf em))))
 188
 189 ;; new, not in closette
 190   ;;; FIXME: this is not actually sufficient argument checking
 191 (defun required-portion (gf args)
 192   (let ((number-required
 193           (sb-pcl::arg-info-number-required (sb-pcl::gf-arg-info gf))))
 194     (when (< (length args) number-required)
 195       (error "Too few arguments to generic function ~S." gf))
 196     (subseq args 0 number-required)))
 197
 198 (defgeneric generalizers-of-using-class (generic-function args))
 199
 200 (defmethod generalizers-of-using-class ((generic-function specializable-generic-function) args)
 201   (mapcar (lambda (arg) (generalizer-of-using-class generic-function arg))
 202           (required-portion generic-function args)))
 203
 204 (defgeneric generalizer-of-using-class (generic-function object))
 205 (defmethod generalizer-of-using-class ((generic-function specializable-generic-function) object)
 206   (class-of object))
 207
 208 (defgeneric specializer-accepts-generalizer-p (gf specializer generalizer))
 209 (defmethod specializer-accepts-generalizer-p
 210     ((gf specializable-generic-function) (specializer class) (generalizer class))
 211   (if (subtypep generalizer specializer)
 212       (values t t)
 213       (values nil t)))
 214 (defmethod specializer-accepts-generalizer-p
 215     ((gf specializable-generic-function) (specializer sb-mop:eql-specializer) (generalizer class))
 216   (if (eq generalizer (class-of (sb-mop:eql-specializer-object specializer)))
 217       (values t nil)
 218       (values nil t)))
 219
 220 (defgeneric compute-applicable-methods-using-generalizers (gf generalizers))
 221 (defmethod compute-applicable-methods-using-generalizers
 222     ((gf specializable-generic-function) generalizers)
 223   ;; differs from closette
 224   (let ((result-definitive-p t))
 225     (flet ((filter (method)
 226              (every (lambda (s g)
 227                       (multiple-value-bind (acceptsp definitivep)
 228                           (specializer-accepts-generalizer-p gf s g)
 229                         (unless definitivep
 230                           (setf result-definitive-p nil))
 231                         acceptsp))
 232                     (sb-mop:method-specializers method) generalizers))
 233            (sorter (m1 m2)
 234              (method-more-specific-p gf m1 m2 generalizers)))
 235       (values
 236        (sort
 237         (copy-list (remove-if-not #'filter (sb-mop:generic-function-methods gf)))
 238         #'sorter)
 239        result-definitive-p))))
 240
 241 ;; new, not in closette
 242 (defgeneric specializer-accepts-p (specializer object))
 243 (defmethod specializer-accepts-p ((specializer class) object)
 244   (typep object specializer))
 245 (defmethod specializer-accepts-p ((specializer sb-mop:eql-specializer) object)
 246   (eq object (sb-mop:eql-specializer-object specializer)))
 247
 248 (defmethod compute-applicable-methods
 249     ((gf specializable-generic-function) arguments)
 250   ;; new, not in closette
 251   (sort
 252    (copy-list
 253     (remove-if-not #'(lambda (method)
 254                        (every #'specializer-accepts-p
 255                               (sb-mop:method-specializers method)
 256                               arguments))
 257                    (sb-mop:generic-function-methods gf)))
 258    (let ((generalizers (generalizers-of-using-class gf arguments)))
 259      (lambda (m1 m2)
 260        (method-more-specific-p gf m1 m2 generalizers)))))
 261
 262 (defun method-more-specific-p (gf method1 method2 generalizers)
 263   ;; FIXME: argument precedence order
 264   (block nil
 265     (mapc #'(lambda (spec1 spec2 generalizer)
 266               (ecase (specializer< gf spec1 spec2 generalizer)
 267                 (< (return t))
 268                 (=)
 269                 ((nil > /=) (return nil))))
 270           (sb-mop:method-specializers method1)
 271           (sb-mop:method-specializers method2)
 272           generalizers)
 273     nil))
 274
 275 ;; new, not in closette
 276 (defgeneric specializer< (gf s1 s2 generalizer))
 277 (defmethod specializer<
 278     ((gf specializable-generic-function) (s1 class) (s2 class) (generalizer class))
 279   (if (eq s1 s2)
 280       '=
 281       (let ((cpl (sb-mop:class-precedence-list generalizer)))
 282         (if (find s2 (cdr (member s1 cpl)))
 283             '<
 284             '>))))
 285 (defmethod specializer<
 286     ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 sb-mop:eql-specializer) generalizer)
 287   (declare (ignore generalizer))
 288   (if (eq (sb-mop:eql-specializer-object s1) (sb-mop:eql-specializer-object s2))
 289       '=
 290       nil))
 291 (defmethod specializer< ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 class) generalizer)
 292   (declare (ignore generalizer))
 293   '<)
 294 (defmethod specializer< ((gf specializable-generic-function) (c1 class) (c2 sb-mop:eql-specializer) generalizer)
 295   (declare (ignore generalizer))
 296   '>)