specializable.lisp

   1 ;;; written by David Lichteblau, based on code by Christophe Rhodes,
   2 ;;; Closette, and SBCL
   3 ;;;
   4 ;;; http://www.lichteblau.com/git/?p=specializable.git;a=blob_plain;f=specializable.lisp;hb=eb30d235951c3c1d128811278760f1db36cd336c
   5
   6 (defpackage "SPECIALIZABLE"
   7   (:use "CL" "SB-EXT")
   8   (:export "SPECIALIZABLE-GENERIC-FUNCTION" "SPECIALIZABLE-METHOD"
   9            "EXTENDED-SPECIALIZER"
  10
  11            "SPECIALIZER-ACCEPTS-P" "SPECIALIZER-ACCEPTS-GENERALIZER-P"
  12            "SPECIALIZER<"
  13
  14            "GENERALIZER-OF-USING-CLASS"
  15            "COMPUTE-APPLICABLE-METHODS-USING-GENERALIZERS"
  16            "GENERALIZER-EQUAL-HASH-KEY"
  17
  18            "DEFINE-EXTENDED-SPECIALIZER"))
  19
  20 (in-package "SPECIALIZABLE")
  21
  22 (defclass extended-specializer (sb-mop:specializer)
  23   ((direct-methods-table :allocation :class
  24                          :initform nil :accessor direct-methods-table)))
  25
  26 (defmethod sb-mop:add-direct-method ((specializer extended-specializer) method)
  27   (let* ((table (direct-methods-table specializer))
  28          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  29     (unless cell
  30       (setf cell (cons specializer nil))
  31       (push cell (direct-methods-table specializer)))
  32     (push method (cdr cell))))
  33
  34 (defmethod sb-mop:remove-direct-method ((specializer extended-specializer) method)
  35   (let* ((table (direct-methods-table specializer))
  36          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  37     (setf (cdr cell) (remove method (cdr cell)))))
  38
  39 (defmethod sb-mop:specializer-direct-methods ((specializer extended-specializer))
  40   (cdr (assoc specializer (direct-methods-table specializer)
  41               :test #'sb-pcl::same-specializer-p)))
  42 (defmethod sb-mop:specializer-direct-generic-functions ((specializer extended-specializer))
  43   (remove-duplicates (mapcar #'sb-mop:method-generic-function (sb-mop:specializer-direct-methods specializer))))
  44
  45 (defclass specializable-generic-function (standard-generic-function)
  46   ((extended-specializers :initform (make-hash-table :test 'equal)
  47                           :reader generic-function-extended-specializers)
  48    (emf-table :initform (make-hash-table :test 'equal) :reader emf-table))
  49   (:metaclass sb-mop:funcallable-standard-class)
  50   (:default-initargs :method-class (find-class 'specializable-method)))
  51
  52 (defclass specializable-method (standard-method)
  53   ((lambda-expression :initarg :lambda-expression
  54                       :accessor specializable-method-lambda-expression)))
  55
  56 (defmacro define-extended-specializer (name (gf-var &rest args) &body body)
  57   ;; FIXME: unparser
  58   `(setf (get ',name 'extended-specializer-parser)
  59          (lambda (,gf-var ,@args)
  60            ,@body)))
  61
  62 ;; doesn't work, because we'd have to dump GF into the fasl for the macro
  63 ;; expansion
  64 ;;; (defun intern-extended-specializer (gf sname)
  65 ;;;   (destructuring-bind (kind &rest args) sname
  66 ;;;     (setf (gethash sname (generic-function-extended-specializers gf))
  67 ;;;       (apply (or (get kind 'extended-specializer-parser)
  68 ;;;                  (error "not declared as an extended specializer name: ~A"
  69 ;;;                         kind))
  70 ;;;              gf
  71 ;;;              args))))
  72
  73 ;;; FIXME: this (and add/remove-direct-method) don't actually work
  74 ;;; together, because two distinct calls to make-extended-specializer
  75 ;;; return two distinct specializer objects.  We need either to make
  76 ;;; the extended specializers be interned, or to have them be
  77 ;;; arbitrarily ephemeral but adjust specializer-direct-methods (and
  78 ;;; implement specializer-direct-generic-functions) accordingly.
  79 (defun make-extended-specializer (sname)
  80   (destructuring-bind (kind &rest args) sname
  81     (apply (or (get kind 'extended-specializer-parser)
  82                (error "not declared as an extended specializer name: ~A"
  83                       kind))
  84            '|This is not a generic function| ;fixme, see comment above
  85            args)))
  86
  87 ;;; from SBCL:
  88
  89 (defmethod sb-pcl:parse-specializer-using-class
  90     ((gf specializable-generic-function) name)
  91   (cond
  92     ((typep name 'sb-mop:specializer) name)
  93     ((symbolp name) (find-class name))
  94     ((consp name)
  95      (case (car name)
  96        (eql (sb-mop:intern-eql-specializer (cadr name)))
  97        (t (make-extended-specializer name))))
  98     (t (error "unexpected specializer name"))))
  99
 100 (defmethod sb-pcl:make-method-specializers-form
 101     ((gf specializable-generic-function) method snames env)
 102   (declare (ignore method env))
 103   (flet ((parse (name)
 104            (cond
 105              ((typep name 'sb-mop:specializer) name)
 106              ((symbolp name) `(find-class ',name))
 107              ((consp name)
 108               (case (car name)
 109                 (eql `(sb-mop:intern-eql-specializer ,(cadr name)))
 110                 (t `(make-extended-specializer ',name))))
 111              (t (error "unexpected specializer name")))))
 112     `(list ,@(mapcar #'parse snames))))
 113
 114 ;;; from Closette, changed to use some SBCL functions:
 115
 116 ;;; FIXME: this is not actually sufficient argument checking
 117 (defun required-portion (gf args)
 118   (let ((number-required
 119          (sb-pcl::arg-info-number-required (sb-pcl::gf-arg-info gf))))
 120     (when (< (length args) number-required)
 121       (error "Too few arguments to generic function ~S." gf))
 122     (subseq args 0 number-required)))
 123
 124 (defgeneric generalizer-equal-hash-key (generic-function generalizer))
 125 (defmethod generalizer-equal-hash-key
 126     ((gf specializable-generic-function) (g class))
 127   (sb-pcl::class-wrapper g))
 128
 129 ;;; FIXME: in some kind of order, the discriminating function needs to handle:
 130 ;;; - argument count checking;
 131 ;;; - keyword argument validity;
 132 ;;; - DONE flushing the emf cache on method addition/removal
 133 ;;; - DONE (sort of, using wrappers/g-e-h-k) flushing the cache on class redefinition;
 134 ;;; - cache thread-safety.
 135 (defmethod sb-mop:compute-discriminating-function ((gf specializable-generic-function))
 136   (lambda (&rest args)
 137     (let* ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 138                                  (required-portion gf args)))
 139            (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers))
 140            (emfun (gethash keys (emf-table gf) nil)))
 141       (if emfun
 142           (sb-pcl::invoke-emf emfun args)
 143           (slow-method-lookup gf args generalizers)))))
 144
 145 (defmethod reinitialize-instance :after ((gf specializable-generic-function) &key)
 146   (clrhash (emf-table gf)))
 147
 148 (defun slow-method-lookup (gf args generalizers)
 149   ;; differs from closette
 150   (multiple-value-bind (applicable-methods definitivep)
 151       (compute-applicable-methods-using-generalizers gf generalizers)
 152     (if definitivep
 153         (let* ((emfun
 154                 (compute-effective-method-function gf applicable-methods))
 155                (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers)))
 156           (setf (gethash keys (emf-table gf)) emfun)
 157           (sb-pcl::invoke-emf emfun args))
 158         (sb-pcl::invoke-emf (compute-effective-method-function
 159                              gf (sb-mop:compute-applicable-methods gf args))
 160                             args))))
 161
 162 (defun compute-effective-method-function (gf methods)
 163   (let* ((mc (sb-mop:generic-function-method-combination gf))
 164          (em (sb-mop:compute-effective-method gf mc methods)))
 165     (sb-pcl::make-effective-method-function gf em)))
 166
 167 ;; new, not in closette
 168 (defgeneric generalizer-of-using-class (generic-function object))
 169 (defmethod generalizer-of-using-class ((generic-function specializable-generic-function) object)
 170   (class-of object))
 171
 172 (defgeneric specializer-accepts-generalizer-p (gf specializer generalizer))
 173 (defmethod specializer-accepts-generalizer-p
 174     ((gf specializable-generic-function) (specializer class) (generalizer class))
 175   (if (subtypep generalizer specializer)
 176       (values t t)
 177       (values nil t)))
 178 (defmethod specializer-accepts-generalizer-p
 179     ((gf specializable-generic-function) (specializer sb-mop:eql-specializer) (generalizer class))
 180   (if (eq generalizer (class-of (sb-mop:eql-specializer-object specializer)))
 181       (values t nil)
 182       (values nil t)))
 183
 184 (defgeneric compute-applicable-methods-using-generalizers (gf generalizers))
 185 (defmethod compute-applicable-methods-using-generalizers
 186     ((gf specializable-generic-function) generalizers)
 187   ;; differs from closette
 188   (let ((result-definitive-p t))
 189     (flet ((filter (method)
 190              (every (lambda (s g)
 191                       (multiple-value-bind (acceptsp definitivep)
 192                           (specializer-accepts-generalizer-p gf s g)
 193                         (unless definitivep
 194                           (setf result-definitive-p nil))
 195                         acceptsp))
 196                     (sb-mop:method-specializers method) generalizers))
 197            (sorter (m1 m2)
 198              (method-more-specific-p gf m1 m2 generalizers)))
 199       (values
 200        (sort
 201         (copy-list (remove-if-not #'filter (sb-mop:generic-function-methods gf)))
 202         #'sorter)
 203        result-definitive-p))))
 204
 205 ;; new, not in closette
 206 (defgeneric specializer-accepts-p (specializer object))
 207 (defmethod specializer-accepts-p ((specializer class) object)
 208   (typep object specializer))
 209 (defmethod specializer-accepts-p ((specializer sb-mop:eql-specializer) object)
 210   (eq object (sb-mop:eql-specializer-object specializer)))
 211
 212 (defmethod compute-applicable-methods
 213     ((gf specializable-generic-function) arguments)
 214   ;; new, not in closette
 215   (sort
 216    (copy-list
 217     (remove-if-not #'(lambda (method)
 218                        (every #'specializer-accepts-p
 219                               (sb-mop:method-specializers method)
 220                               arguments))
 221                    (sb-mop:generic-function-methods gf)))
 222    (let ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 223                                (required-portion gf arguments))))
 224      (lambda (m1 m2)
 225        (method-more-specific-p gf m1 m2 generalizers)))))
 226
 227 (defun method-more-specific-p (gf method1 method2 generalizers)
 228   ;; FIXME: argument precedence order
 229   (block nil
 230     (mapc #'(lambda (spec1 spec2 generalizer)
 231               (ecase (specializer< gf spec1 spec2 generalizer)
 232                 (< (return t))
 233                 (=)
 234                 ((nil > /=) (return nil))))
 235           (sb-mop:method-specializers method1)
 236           (sb-mop:method-specializers method2)
 237           generalizers)
 238     nil))
 239
 240 ;; new, not in closette
 241 (defgeneric specializer< (gf s1 s2 generalizer))
 242 (defmethod specializer<
 243     ((gf specializable-generic-function) (s1 class) (s2 class) (generalizer class))
 244   (if (eq s1 s2)
 245       '=
 246       (let ((cpl (sb-mop:class-precedence-list generalizer)))
 247         (if (find s2 (cdr (member s1 cpl)))
 248             '<
 249             '>))))
 250 (defmethod specializer<
 251     ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 sb-mop:eql-specializer) generalizer)
 252   (declare (ignore generalizer))
 253   (if (eq (sb-mop:eql-specializer-object s1) (sb-mop:eql-specializer-object s2))
 254       '=
 255       nil))
 256 (defmethod specializer< ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 class) generalizer)
 257   (declare (ignore generalizer))
 258   '<)
 259 (defmethod specializer< ((gf specializable-generic-function) (c1 class) (c2 sb-mop:eql-specializer) generalizer)
 260   (declare (ignore generalizer))
 261   '>)