specializable.lisp

   1 ;;; written by David Lichteblau, based on code by Christophe Rhodes,
   2 ;;; Closette, and SBCL
   3 ;;;
   4 ;;; http://www.lichteblau.com/git/?p=specializable.git;a=blob_plain;f=specializable.lisp;hb=eb30d235951c3c1d128811278760f1db36cd336c
   5
   6 (defpackage "SPECIALIZABLE"
   7   (:use "CL" "SB-EXT")
   8   (:export "SPECIALIZABLE-GENERIC-FUNCTION" "SPECIALIZABLE-METHOD"
   9            "EXTENDED-SPECIALIZER"
  10
  11            "SPECIALIZER-ACCEPTS-P" "SPECIALIZER-ACCEPTS-GENERALIZER-P"
  12            "SPECIALIZER<"
  13
  14            "GENERALIZER-OF-USING-CLASS"
  15            "COMPUTE-APPLICABLE-METHODS-USING-GENERALIZERS"
  16            "GENERALIZER-EQUAL-HASH-KEY"
  17
  18            "DEFINE-EXTENDED-SPECIALIZER"))
  19
  20 (in-package "SPECIALIZABLE")
  21
  22 (defclass extended-specializer (sb-mop:specializer)
  23   ((direct-methods :initform nil
  24                    :accessor %specializer-direct-methods
  25                    :reader specializer-direct-methods)))
  26
  27 (defclass specializable-generic-function (standard-generic-function)
  28   ((extended-specializers :initform (make-hash-table :test 'equal)
  29                           :reader generic-function-extended-specializers)
  30    (emf-table :initform (make-hash-table :test 'equal) :reader emf-table))
  31   (:metaclass sb-mop:funcallable-standard-class)
  32   (:default-initargs :method-class (find-class 'specializable-method)))
  33
  34 (defclass specializable-method (standard-method)
  35   ((lambda-expression :initarg :lambda-expression
  36                       :accessor specializable-method-lambda-expression)))
  37
  38 (defmacro define-extended-specializer (name (gf-var &rest args) &body body)
  39   ;; FIXME: unparser
  40   `(setf (get ',name 'extended-specializer-parser)
  41          (lambda (,gf-var ,@args)
  42            ,@body)))
  43
  44 ;; doesn't work, because we'd have to dump GF into the fasl for the macro
  45 ;; expansion
  46 ;;; (defun intern-extended-specializer (gf sname)
  47 ;;;   (destructuring-bind (kind &rest args) sname
  48 ;;;     (setf (gethash sname (generic-function-extended-specializers gf))
  49 ;;;       (apply (or (get kind 'extended-specializer-parser)
  50 ;;;                  (error "not declared as an extended specializer name: ~A"
  51 ;;;                         kind))
  52 ;;;              gf
  53 ;;;              args))))
  54
  55 ;;; FIXME: this (and add/remove-direct-method) don't actually work
  56 ;;; together, because two distinct calls to make-extended-specializer
  57 ;;; return two distinct specializer objects.  We need either to make
  58 ;;; the extended specializers be interned, or to have them be
  59 ;;; arbitrarily ephemeral but adjust specializer-direct-methods (and
  60 ;;; implement specializer-direct-generic-functions) accordingly.
  61 (defun make-extended-specializer (sname)
  62   (destructuring-bind (kind &rest args) sname
  63     (apply (or (get kind 'extended-specializer-parser)
  64                (error "not declared as an extended specializer name: ~A"
  65                       kind))
  66            '|This is not a generic function| ;fixme, see comment above
  67            args)))
  68
  69 (defmethod sb-mop:add-direct-method ((specializer extended-specializer) method)
  70   (pushnew method (%specializer-direct-methods specializer)))
  71
  72 (defmethod sb-mop:remove-direct-method ((specializer extended-specializer) method)
  73   (setf (%specializer-direct-methods specializer)
  74         (remove method (specializer-direct-methods specializer))))
  75
  76 ;;; from SBCL:
  77
  78 (defmethod sb-pcl:parse-specializer-using-class
  79     ((gf specializable-generic-function) name)
  80   (cond
  81     ((typep name 'sb-mop:specializer) name)
  82     ((symbolp name) (find-class name))
  83     ((consp name)
  84      (case (car name)
  85        (eql (sb-mop:intern-eql-specializer (cadr name)))
  86        (t (make-extended-specializer name))))
  87     (t (error "unexpected specializer name"))))
  88
  89 (defmethod sb-pcl:make-method-specializers-form
  90     ((gf specializable-generic-function) method snames env)
  91   (declare (ignore method env))
  92   (flet ((parse (name)
  93            (cond
  94              ((typep name 'sb-mop:specializer) name)
  95              ((symbolp name) `(find-class ',name))
  96              ((consp name)
  97               (case (car name)
  98                 (eql `(sb-mop:intern-eql-specializer ,(cadr name)))
  99                 (t `(make-extended-specializer ',name))))
 100              (t (error "unexpected specializer name")))))
 101     `(list ,@(mapcar #'parse snames))))
 102
 103 ;;; from Closette, changed to use some SBCL functions:
 104
 105 ;;; FIXME: this is not actually sufficient argument checking
 106 (defun required-portion (gf args)
 107   (let ((number-required
 108          (sb-pcl::arg-info-number-required (sb-pcl::gf-arg-info gf))))
 109     (when (< (length args) number-required)
 110       (error "Too few arguments to generic function ~S." gf))
 111     (subseq args 0 number-required)))
 112
 113 (defgeneric generalizer-equal-hash-key (generic-function generalizer))
 114 (defmethod generalizer-equal-hash-key
 115     ((gf specializable-generic-function) (g class))
 116   (sb-pcl::class-wrapper g))
 117
 118 ;;; FIXME: in some kind of order, the discriminating function needs to handle:
 119 ;;; - argument count checking;
 120 ;;; - keyword argument validity;
 121 ;;; - DONE flushing the emf cache on method addition/removal
 122 ;;; - DONE (sort of, using wrappers/g-e-h-k) flushing the cache on class redefinition;
 123 ;;; - cache thread-safety.
 124 (defmethod sb-mop:compute-discriminating-function ((gf specializable-generic-function))
 125   (lambda (&rest args)
 126     (let* ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 127                                  (required-portion gf args)))
 128            (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers))
 129            (emfun (gethash keys (emf-table gf) nil)))
 130       (if emfun
 131           (sb-pcl::invoke-emf emfun args)
 132           (slow-method-lookup gf args generalizers)))))
 133
 134 (defmethod reinitialize-instance :after ((gf specializable-generic-function) &key)
 135   (clrhash (emf-table gf)))
 136
 137 (defun slow-method-lookup (gf args generalizers)
 138   ;; differs from closette
 139   (multiple-value-bind (applicable-methods definitivep)
 140       (compute-applicable-methods-using-generalizers gf generalizers)
 141     (if definitivep
 142         (let* ((emfun
 143                 (compute-effective-method-function gf applicable-methods))
 144                (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers)))
 145           (setf (gethash keys (emf-table gf)) emfun)
 146           (sb-pcl::invoke-emf emfun args))
 147         (sb-pcl::invoke-emf (compute-effective-method-function
 148                              gf (sb-mop:compute-applicable-methods gf args))
 149                             args))))
 150
 151 (defun compute-effective-method-function (gf methods)
 152   (let* ((mc (sb-mop:generic-function-method-combination gf))
 153          (em (sb-mop:compute-effective-method gf mc methods)))
 154     (sb-pcl::make-effective-method-function gf em)))
 155
 156 ;; new, not in closette
 157 (defgeneric generalizer-of-using-class (generic-function object))
 158 (defmethod generalizer-of-using-class ((generic-function specializable-generic-function) object)
 159   (class-of object))
 160
 161 (defgeneric specializer-accepts-generalizer-p (gf specializer generalizer))
 162 (defmethod specializer-accepts-generalizer-p
 163     ((gf specializable-generic-function) (specializer class) (generalizer class))
 164   (if (subtypep generalizer specializer)
 165       (values t t)
 166       (values nil t)))
 167 (defmethod specializer-accepts-generalizer-p
 168     ((gf specializable-generic-function) (specializer sb-mop:eql-specializer) (generalizer class))
 169   (if (eq generalizer (class-of (sb-mop:eql-specializer-object specializer)))
 170       (values t nil)
 171       (values nil t)))
 172
 173 (defgeneric compute-applicable-methods-using-generalizers (gf generalizers))
 174 (defmethod compute-applicable-methods-using-generalizers
 175     ((gf specializable-generic-function) generalizers)
 176   ;; differs from closette
 177   (let ((result-definitive-p t))
 178     (flet ((filter (method)
 179              (every (lambda (s g)
 180                       (multiple-value-bind (acceptsp definitivep)
 181                           (specializer-accepts-generalizer-p gf s g)
 182                         (unless definitivep
 183                           (setf result-definitive-p nil))
 184                         acceptsp))
 185                     (sb-mop:method-specializers method) generalizers))
 186            (sorter (m1 m2)
 187              (method-more-specific-p gf m1 m2 generalizers)))
 188       (values
 189        (sort
 190         (copy-list (remove-if-not #'filter (sb-mop:generic-function-methods gf)))
 191         #'sorter)
 192        result-definitive-p))))
 193
 194 ;; new, not in closette
 195 (defgeneric specializer-accepts-p (specializer object))
 196 (defmethod specializer-accepts-p ((specializer class) object)
 197   (typep object specializer))
 198 (defmethod specializer-accepts-p ((specializer sb-mop:eql-specializer) object)
 199   (eq object (sb-mop:eql-specializer-object specializer)))
 200
 201 (defmethod compute-applicable-methods
 202     ((gf specializable-generic-function) arguments)
 203   ;; new, not in closette
 204   (sort
 205    (copy-list
 206     (remove-if-not #'(lambda (method)
 207                        (every #'specializer-accepts-p
 208                               (sb-mop:method-specializers method)
 209                               arguments))
 210                    (sb-mop:generic-function-methods gf)))
 211    (let ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 212                                (required-portion gf arguments))))
 213      (lambda (m1 m2)
 214        (method-more-specific-p gf m1 m2 generalizers)))))
 215
 216 (defun method-more-specific-p (gf method1 method2 generalizers)
 217   ;; FIXME: argument precedence order
 218   (block nil
 219     (mapc #'(lambda (spec1 spec2 generalizer)
 220               (ecase (specializer< gf spec1 spec2 generalizer)
 221                 (< (return t))
 222                 (=)
 223                 ((nil > /=) (return nil))))
 224           (sb-mop:method-specializers method1)
 225           (sb-mop:method-specializers method2)
 226           generalizers)
 227     nil))
 228
 229 ;; new, not in closette
 230 (defgeneric specializer< (gf s1 s2 generalizer))
 231 (defmethod specializer<
 232     ((gf specializable-generic-function) (s1 class) (s2 class) (generalizer class))
 233   (if (eq s1 s2)
 234       '=
 235       (let ((cpl (sb-mop:class-precedence-list generalizer)))
 236         (if (find s2 (cdr (member s1 cpl)))
 237             '<
 238             '>))))
 239 (defmethod specializer<
 240     ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 sb-mop:eql-specializer) generalizer)
 241   (declare (ignore generalizer))
 242   (if (eq (sb-mop:eql-specializer-object s1) (sb-mop:eql-specializer-object s2))
 243       '=
 244       nil))
 245 (defmethod specializer< ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 class) generalizer)
 246   (declare (ignore generalizer))
 247   '<)
 248 (defmethod specializer< ((gf specializable-generic-function) (c1 class) (c2 sb-mop:eql-specializer) generalizer)
 249   (declare (ignore generalizer))
 250   '>)