specializable.lisp

   1 ;;; written by David Lichteblau, based on code by Christophe Rhodes,
   2 ;;; Closette, and SBCL
   3 ;;;
   4 ;;; http://www.lichteblau.com/git/?p=specializable.git;a=blob_plain;f=specializable.lisp;hb=eb30d235951c3c1d128811278760f1db36cd336c
   5
   6 (defpackage "SPECIALIZABLE"
   7   (:use "CL" "SB-EXT")
   8   (:export "SPECIALIZABLE-GENERIC-FUNCTION" "SPECIALIZABLE-METHOD"
   9            "EXTENDED-SPECIALIZER"
  10
  11            "SPECIALIZER-ACCEPTS-P" "SPECIALIZER-ACCEPTS-GENERALIZER-P"
  12            "SPECIALIZER<"
  13
  14            "GENERALIZER-OF-USING-CLASS"
  15            "COMPUTE-APPLICABLE-METHODS-USING-GENERALIZERS"
  16            "GENERALIZER-EQUAL-HASH-KEY"
  17
  18            "DEFINE-EXTENDED-SPECIALIZER"))
  19
  20 (in-package "SPECIALIZABLE")
  21
  22 (defclass extended-specializer (sb-mop:specializer)
  23   ;; FIXME: this doesn't actually do quite what I wanted.
  24   ((direct-methods-table :allocation :class
  25                          :initform nil :accessor direct-methods-table)))
  26
  27 (defmethod sb-mop:add-direct-method ((specializer extended-specializer) method)
  28   (let* ((table (direct-methods-table specializer))
  29          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  30     (unless cell
  31       (setf cell (cons specializer nil))
  32       (push cell (direct-methods-table specializer)))
  33     (push method (cdr cell))))
  34
  35 (defmethod sb-mop:remove-direct-method ((specializer extended-specializer) method)
  36   (let* ((table (direct-methods-table specializer))
  37          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  38     (setf (cdr cell) (remove method (cdr cell)))))
  39
  40 (defmethod sb-mop:specializer-direct-methods ((specializer extended-specializer))
  41   (cdr (assoc specializer (direct-methods-table specializer)
  42               :test #'sb-pcl::same-specializer-p)))
  43 (defmethod sb-mop:specializer-direct-generic-functions ((specializer extended-specializer))
  44   (remove-duplicates (mapcar #'sb-mop:method-generic-function (sb-mop:specializer-direct-methods specializer))))
  45
  46 (defclass specializable-generic-function (standard-generic-function)
  47   ((extended-specializers :initform (make-hash-table :test 'equal)
  48                           :reader generic-function-extended-specializers)
  49    (emf-table :initform (make-hash-table :test 'equal) :reader emf-table))
  50   (:metaclass sb-mop:funcallable-standard-class)
  51   (:default-initargs :method-class (find-class 'specializable-method)))
  52
  53 (defclass specializable-method (standard-method)
  54   ((lambda-expression :initarg :lambda-expression
  55                       :accessor specializable-method-lambda-expression)))
  56
  57 (defmacro define-extended-specializer (name (gf-var &rest args) &body body)
  58   ;; FIXME: unparser
  59   `(setf (get ',name 'extended-specializer-parser)
  60          (lambda (,gf-var ,@args)
  61            ,@body)))
  62
  63 ;; doesn't work, because we'd have to dump GF into the fasl for the macro
  64 ;; expansion
  65 ;;; (defun intern-extended-specializer (gf sname)
  66 ;;;   (destructuring-bind (kind &rest args) sname
  67 ;;;     (setf (gethash sname (generic-function-extended-specializers gf))
  68 ;;;       (apply (or (get kind 'extended-specializer-parser)
  69 ;;;                  (error "not declared as an extended specializer name: ~A"
  70 ;;;                         kind))
  71 ;;;              gf
  72 ;;;              args))))
  73
  74 (defun make-extended-specializer (sname)
  75   (destructuring-bind (kind &rest args) sname
  76     (apply (or (get kind 'extended-specializer-parser)
  77                (error "not declared as an extended specializer name: ~A"
  78                       kind))
  79            '|This is not a generic function| ;fixme, see comment above
  80            args)))
  81
  82 ;;; from SBCL:
  83
  84 (defmethod sb-pcl:parse-specializer-using-class
  85     ((gf specializable-generic-function) name)
  86   (cond
  87     ((typep name 'sb-mop:specializer) name)
  88     ((symbolp name) (find-class name))
  89     ((consp name)
  90      (case (car name)
  91        (eql (sb-mop:intern-eql-specializer (cadr name)))
  92        (t (make-extended-specializer name))))
  93     (t (error "unexpected specializer name"))))
  94
  95 (defmethod sb-pcl:make-method-specializers-form
  96     ((gf specializable-generic-function) method snames env)
  97   (declare (ignore method env))
  98   (flet ((parse (name)
  99            (cond
 100              ((typep name 'sb-mop:specializer) name)
 101              ((symbolp name) `(find-class ',name))
 102              ((consp name)
 103               (case (car name)
 104                 (eql `(sb-mop:intern-eql-specializer ,(cadr name)))
 105                 (t `(make-extended-specializer ',name))))
 106              (t (error "unexpected specializer name")))))
 107     `(list ,@(mapcar #'parse snames))))
 108
 109 ;;; from Closette, changed to use some SBCL functions:
 110
 111 ;;; FIXME: this is not actually sufficient argument checking
 112 (defun required-portion (gf args)
 113   (let ((number-required
 114          (sb-pcl::arg-info-number-required (sb-pcl::gf-arg-info gf))))
 115     (when (< (length args) number-required)
 116       (error "Too few arguments to generic function ~S." gf))
 117     (subseq args 0 number-required)))
 118
 119 (defgeneric generalizer-equal-hash-key (generic-function generalizer))
 120 (defmethod generalizer-equal-hash-key
 121     ((gf specializable-generic-function) (g class))
 122   (sb-pcl::class-wrapper g))
 123
 124 (defun first-arg-only-special-case (gf)
 125   (let ((arg-info (sb-pcl::gf-arg-info gf)))
 126     (and (>= (sb-pcl::arg-info-number-required arg-info) 1)
 127          (every (lambda (x) (eql x t))
 128                 (cdr (sb-pcl::arg-info-metatypes arg-info))))))
 129
 130 ;;; FIXME: in some kind of order, the discriminating function needs to handle:
 131 ;;; - argument count checking;
 132 ;;; - DONE (in effective method) keyword argument validity;
 133 ;;; - DONE flushing the emf cache on method addition/removal
 134 ;;; - DONE (sort of, using wrappers/g-e-h-k) flushing the cache on class redefinition;
 135 ;;; - cache thread-safety.
 136 ;;; - speed
 137 ;;; - interaction with TRACE et al.
 138 (defmethod sb-mop:compute-discriminating-function ((gf specializable-generic-function))
 139   (if (first-arg-only-special-case gf)
 140       (lambda (&rest args)
 141         (let* ((g (generalizer-of-using-class gf (car args)))
 142                (k (generalizer-equal-hash-key gf g))
 143                (emfun (gethash k (emf-table gf) nil)))
 144           (if emfun
 145               (sb-pcl::invoke-emf emfun args)
 146               (slow-method-lookup gf args (cons g (mapcar (lambda (x) (generalizer-of-using-class gf x))
 147                                                           (cdr (required-portion gf args))))))))
 148       (lambda (&rest args)
 149         (let* ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 150                                      (required-portion gf args)))
 151                (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers))
 152                (emfun (gethash keys (emf-table gf) nil)))
 153           (if emfun
 154               (sb-pcl::invoke-emf emfun args)
 155               (slow-method-lookup gf args generalizers))))))
 156
 157 (defmethod reinitialize-instance :after ((gf specializable-generic-function) &key)
 158   (clrhash (emf-table gf)))
 159
 160 (defun slow-method-lookup (gf args generalizers)
 161   ;; differs from closette
 162   (multiple-value-bind (applicable-methods definitivep)
 163       (compute-applicable-methods-using-generalizers gf generalizers)
 164     (if definitivep
 165         (let* ((emfun
 166                 (compute-effective-method-function gf applicable-methods))
 167                (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers)))
 168           (if (first-arg-only-special-case gf)
 169               (setf (gethash (car keys) (emf-table gf)) emfun)
 170               (setf (gethash keys (emf-table gf)) emfun))
 171           (sb-pcl::invoke-emf emfun args))
 172         (sb-pcl::invoke-emf (compute-effective-method-function
 173                              gf (sb-mop:compute-applicable-methods gf args))
 174                             args))))
 175
 176 (defun compute-effective-method-function (gf methods)
 177   (if (null methods)
 178       (lambda (&rest args) (apply #'no-applicable-method gf args))
 179       (let* ((mc (sb-mop:generic-function-method-combination gf))
 180              (sb-pcl::*applicable-methods* methods)
 181              (em (sb-mop:compute-effective-method gf mc methods)))
 182         (sb-pcl::make-effective-method-function gf em))))
 183
 184 ;; new, not in closette
 185 (defgeneric generalizer-of-using-class (generic-function object))
 186 (defmethod generalizer-of-using-class ((generic-function specializable-generic-function) object)
 187   (class-of object))
 188
 189 (defgeneric specializer-accepts-generalizer-p (gf specializer generalizer))
 190 (defmethod specializer-accepts-generalizer-p
 191     ((gf specializable-generic-function) (specializer class) (generalizer class))
 192   (if (subtypep generalizer specializer)
 193       (values t t)
 194       (values nil t)))
 195 (defmethod specializer-accepts-generalizer-p
 196     ((gf specializable-generic-function) (specializer sb-mop:eql-specializer) (generalizer class))
 197   (if (eq generalizer (class-of (sb-mop:eql-specializer-object specializer)))
 198       (values t nil)
 199       (values nil t)))
 200
 201 (defgeneric compute-applicable-methods-using-generalizers (gf generalizers))
 202 (defmethod compute-applicable-methods-using-generalizers
 203     ((gf specializable-generic-function) generalizers)
 204   ;; differs from closette
 205   (let ((result-definitive-p t))
 206     (flet ((filter (method)
 207              (every (lambda (s g)
 208                       (multiple-value-bind (acceptsp definitivep)
 209                           (specializer-accepts-generalizer-p gf s g)
 210                         (unless definitivep
 211                           (setf result-definitive-p nil))
 212                         acceptsp))
 213                     (sb-mop:method-specializers method) generalizers))
 214            (sorter (m1 m2)
 215              (method-more-specific-p gf m1 m2 generalizers)))
 216       (values
 217        (sort
 218         (copy-list (remove-if-not #'filter (sb-mop:generic-function-methods gf)))
 219         #'sorter)
 220        result-definitive-p))))
 221
 222 ;; new, not in closette
 223 (defgeneric specializer-accepts-p (specializer object))
 224 (defmethod specializer-accepts-p ((specializer class) object)
 225   (typep object specializer))
 226 (defmethod specializer-accepts-p ((specializer sb-mop:eql-specializer) object)
 227   (eq object (sb-mop:eql-specializer-object specializer)))
 228
 229 (defmethod compute-applicable-methods
 230     ((gf specializable-generic-function) arguments)
 231   ;; new, not in closette
 232   (sort
 233    (copy-list
 234     (remove-if-not #'(lambda (method)
 235                        (every #'specializer-accepts-p
 236                               (sb-mop:method-specializers method)
 237                               arguments))
 238                    (sb-mop:generic-function-methods gf)))
 239    (let ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 240                                (required-portion gf arguments))))
 241      (lambda (m1 m2)
 242        (method-more-specific-p gf m1 m2 generalizers)))))
 243
 244 (defun method-more-specific-p (gf method1 method2 generalizers)
 245   ;; FIXME: argument precedence order
 246   (block nil
 247     (mapc #'(lambda (spec1 spec2 generalizer)
 248               (ecase (specializer< gf spec1 spec2 generalizer)
 249                 (< (return t))
 250                 (=)
 251                 ((nil > /=) (return nil))))
 252           (sb-mop:method-specializers method1)
 253           (sb-mop:method-specializers method2)
 254           generalizers)
 255     nil))
 256
 257 ;; new, not in closette
 258 (defgeneric specializer< (gf s1 s2 generalizer))
 259 (defmethod specializer<
 260     ((gf specializable-generic-function) (s1 class) (s2 class) (generalizer class))
 261   (if (eq s1 s2)
 262       '=
 263       (let ((cpl (sb-mop:class-precedence-list generalizer)))
 264         (if (find s2 (cdr (member s1 cpl)))
 265             '<
 266             '>))))
 267 (defmethod specializer<
 268     ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 sb-mop:eql-specializer) generalizer)
 269   (declare (ignore generalizer))
 270   (if (eq (sb-mop:eql-specializer-object s1) (sb-mop:eql-specializer-object s2))
 271       '=
 272       nil))
 273 (defmethod specializer< ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 class) generalizer)
 274   (declare (ignore generalizer))
 275   '<)
 276 (defmethod specializer< ((gf specializable-generic-function) (c1 class) (c2 sb-mop:eql-specializer) generalizer)
 277   (declare (ignore generalizer))
 278   '>)