specializable.lisp

   1 ;;; written by David Lichteblau, based on code by Christophe Rhodes,
   2 ;;; Closette, and SBCL
   3 ;;;
   4 ;;; http://www.lichteblau.com/git/?p=specializable.git;a=blob_plain;f=specializable.lisp;hb=eb30d235951c3c1d128811278760f1db36cd336c
   5
   6 (defpackage "SPECIALIZABLE"
   7   (:use "CL" "SB-EXT")
   8   (:export "SPECIALIZABLE-GENERIC-FUNCTION" "SPECIALIZABLE-METHOD"
   9            "EXTENDED-SPECIALIZER"
  10
  11            "SPECIALIZER-ACCEPTS-P" "SPECIALIZER-ACCEPTS-GENERALIZER-P"
  12            "SPECIALIZER<"
  13
  14            "GENERALIZER-OF-USING-CLASS"
  15            "COMPUTE-APPLICABLE-METHODS-USING-GENERALIZERS"
  16            "GENERALIZER-EQUAL-HASH-KEY"
  17
  18            "DEFINE-EXTENDED-SPECIALIZER"))
  19
  20 (in-package "SPECIALIZABLE")
  21
  22 (defclass extended-specializer (sb-mop:specializer)
  23   ((direct-methods-table :allocation :class
  24                          :initform nil :accessor direct-methods-table)))
  25
  26 (defmethod sb-mop:add-direct-method ((specializer extended-specializer) method)
  27   (let* ((table (direct-methods-table specializer))
  28          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  29     (unless cell
  30       (setf cell (cons specializer nil))
  31       (push cell (direct-methods-table specializer)))
  32     (push method (cdr cell))))
  33
  34 (defmethod sb-mop:remove-direct-method ((specializer extended-specializer) method)
  35   (let* ((table (direct-methods-table specializer))
  36          (cell (assoc specializer table :test #'sb-pcl::same-specializer-p)))
  37     (setf (cdr cell) (remove method (cdr cell)))))
  38
  39 (defmethod sb-mop:specializer-direct-methods ((specializer extended-specializer))
  40   (cdr (assoc specializer (direct-methods-table specializer)
  41               :test #'sb-pcl::same-specializer-p)))
  42 (defmethod sb-mop:specializer-direct-generic-functions ((specializer extended-specializer))
  43   (remove-duplicates (mapcar #'sb-mop:method-generic-function (sb-mop:specializer-direct-methods specializer))))
  44
  45 (defclass specializable-generic-function (standard-generic-function)
  46   ((extended-specializers :initform (make-hash-table :test 'equal)
  47                           :reader generic-function-extended-specializers)
  48    (emf-table :initform (make-hash-table :test 'equal) :reader emf-table))
  49   (:metaclass sb-mop:funcallable-standard-class)
  50   (:default-initargs :method-class (find-class 'specializable-method)))
  51
  52 (defclass specializable-method (standard-method)
  53   ((lambda-expression :initarg :lambda-expression
  54                       :accessor specializable-method-lambda-expression)))
  55
  56 (defmacro define-extended-specializer (name (gf-var &rest args) &body body)
  57   ;; FIXME: unparser
  58   `(setf (get ',name 'extended-specializer-parser)
  59          (lambda (,gf-var ,@args)
  60            ,@body)))
  61
  62 ;; doesn't work, because we'd have to dump GF into the fasl for the macro
  63 ;; expansion
  64 ;;; (defun intern-extended-specializer (gf sname)
  65 ;;;   (destructuring-bind (kind &rest args) sname
  66 ;;;     (setf (gethash sname (generic-function-extended-specializers gf))
  67 ;;;       (apply (or (get kind 'extended-specializer-parser)
  68 ;;;                  (error "not declared as an extended specializer name: ~A"
  69 ;;;                         kind))
  70 ;;;              gf
  71 ;;;              args))))
  72
  73 (defun make-extended-specializer (sname)
  74   (destructuring-bind (kind &rest args) sname
  75     (apply (or (get kind 'extended-specializer-parser)
  76                (error "not declared as an extended specializer name: ~A"
  77                       kind))
  78            '|This is not a generic function| ;fixme, see comment above
  79            args)))
  80
  81 ;;; from SBCL:
  82
  83 (defmethod sb-pcl:parse-specializer-using-class
  84     ((gf specializable-generic-function) name)
  85   (cond
  86     ((typep name 'sb-mop:specializer) name)
  87     ((symbolp name) (find-class name))
  88     ((consp name)
  89      (case (car name)
  90        (eql (sb-mop:intern-eql-specializer (cadr name)))
  91        (t (make-extended-specializer name))))
  92     (t (error "unexpected specializer name"))))
  93
  94 (defmethod sb-pcl:make-method-specializers-form
  95     ((gf specializable-generic-function) method snames env)
  96   (declare (ignore method env))
  97   (flet ((parse (name)
  98            (cond
  99              ((typep name 'sb-mop:specializer) name)
 100              ((symbolp name) `(find-class ',name))
 101              ((consp name)
 102               (case (car name)
 103                 (eql `(sb-mop:intern-eql-specializer ,(cadr name)))
 104                 (t `(make-extended-specializer ',name))))
 105              (t (error "unexpected specializer name")))))
 106     `(list ,@(mapcar #'parse snames))))
 107
 108 ;;; from Closette, changed to use some SBCL functions:
 109
 110 ;;; FIXME: this is not actually sufficient argument checking
 111 (defun required-portion (gf args)
 112   (let ((number-required
 113          (sb-pcl::arg-info-number-required (sb-pcl::gf-arg-info gf))))
 114     (when (< (length args) number-required)
 115       (error "Too few arguments to generic function ~S." gf))
 116     (subseq args 0 number-required)))
 117
 118 (defgeneric generalizer-equal-hash-key (generic-function generalizer))
 119 (defmethod generalizer-equal-hash-key
 120     ((gf specializable-generic-function) (g class))
 121   (sb-pcl::class-wrapper g))
 122
 123 ;;; FIXME: in some kind of order, the discriminating function needs to handle:
 124 ;;; - argument count checking;
 125 ;;; - DONE (in effective method) keyword argument validity;
 126 ;;; - DONE flushing the emf cache on method addition/removal
 127 ;;; - DONE (sort of, using wrappers/g-e-h-k) flushing the cache on class redefinition;
 128 ;;; - cache thread-safety.
 129 (defmethod sb-mop:compute-discriminating-function ((gf specializable-generic-function))
 130   (lambda (&rest args)
 131     (let* ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 132                                  (required-portion gf args)))
 133            (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers))
 134            (emfun (gethash keys (emf-table gf) nil)))
 135       (if emfun
 136           (sb-pcl::invoke-emf emfun args)
 137           (slow-method-lookup gf args generalizers)))))
 138
 139 (defmethod reinitialize-instance :after ((gf specializable-generic-function) &key)
 140   (clrhash (emf-table gf)))
 141
 142 (defun slow-method-lookup (gf args generalizers)
 143   ;; differs from closette
 144   (multiple-value-bind (applicable-methods definitivep)
 145       (compute-applicable-methods-using-generalizers gf generalizers)
 146     (if definitivep
 147         (let* ((emfun
 148                 (compute-effective-method-function gf applicable-methods))
 149                (keys (mapcar (lambda (x) (generalizer-equal-hash-key gf x)) generalizers)))
 150           (setf (gethash keys (emf-table gf)) emfun)
 151           (sb-pcl::invoke-emf emfun args))
 152         (sb-pcl::invoke-emf (compute-effective-method-function
 153                              gf (sb-mop:compute-applicable-methods gf args))
 154                             args))))
 155
 156 (defun compute-effective-method-function (gf methods)
 157   (let* ((mc (sb-mop:generic-function-method-combination gf))
 158          (sb-pcl::*applicable-methods* methods)
 159          (em (sb-mop:compute-effective-method gf mc methods)))
 160     (sb-pcl::make-effective-method-function gf em)))
 161
 162 ;; new, not in closette
 163 (defgeneric generalizer-of-using-class (generic-function object))
 164 (defmethod generalizer-of-using-class ((generic-function specializable-generic-function) object)
 165   (class-of object))
 166
 167 (defgeneric specializer-accepts-generalizer-p (gf specializer generalizer))
 168 (defmethod specializer-accepts-generalizer-p
 169     ((gf specializable-generic-function) (specializer class) (generalizer class))
 170   (if (subtypep generalizer specializer)
 171       (values t t)
 172       (values nil t)))
 173 (defmethod specializer-accepts-generalizer-p
 174     ((gf specializable-generic-function) (specializer sb-mop:eql-specializer) (generalizer class))
 175   (if (eq generalizer (class-of (sb-mop:eql-specializer-object specializer)))
 176       (values t nil)
 177       (values nil t)))
 178
 179 (defgeneric compute-applicable-methods-using-generalizers (gf generalizers))
 180 (defmethod compute-applicable-methods-using-generalizers
 181     ((gf specializable-generic-function) generalizers)
 182   ;; differs from closette
 183   (let ((result-definitive-p t))
 184     (flet ((filter (method)
 185              (every (lambda (s g)
 186                       (multiple-value-bind (acceptsp definitivep)
 187                           (specializer-accepts-generalizer-p gf s g)
 188                         (unless definitivep
 189                           (setf result-definitive-p nil))
 190                         acceptsp))
 191                     (sb-mop:method-specializers method) generalizers))
 192            (sorter (m1 m2)
 193              (method-more-specific-p gf m1 m2 generalizers)))
 194       (values
 195        (sort
 196         (copy-list (remove-if-not #'filter (sb-mop:generic-function-methods gf)))
 197         #'sorter)
 198        result-definitive-p))))
 199
 200 ;; new, not in closette
 201 (defgeneric specializer-accepts-p (specializer object))
 202 (defmethod specializer-accepts-p ((specializer class) object)
 203   (typep object specializer))
 204 (defmethod specializer-accepts-p ((specializer sb-mop:eql-specializer) object)
 205   (eq object (sb-mop:eql-specializer-object specializer)))
 206
 207 (defmethod compute-applicable-methods
 208     ((gf specializable-generic-function) arguments)
 209   ;; new, not in closette
 210   (sort
 211    (copy-list
 212     (remove-if-not #'(lambda (method)
 213                        (every #'specializer-accepts-p
 214                               (sb-mop:method-specializers method)
 215                               arguments))
 216                    (sb-mop:generic-function-methods gf)))
 217    (let ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 218                                (required-portion gf arguments))))
 219      (lambda (m1 m2)
 220        (method-more-specific-p gf m1 m2 generalizers)))))
 221
 222 (defun method-more-specific-p (gf method1 method2 generalizers)
 223   ;; FIXME: argument precedence order
 224   (block nil
 225     (mapc #'(lambda (spec1 spec2 generalizer)
 226               (ecase (specializer< gf spec1 spec2 generalizer)
 227                 (< (return t))
 228                 (=)
 229                 ((nil > /=) (return nil))))
 230           (sb-mop:method-specializers method1)
 231           (sb-mop:method-specializers method2)
 232           generalizers)
 233     nil))
 234
 235 ;; new, not in closette
 236 (defgeneric specializer< (gf s1 s2 generalizer))
 237 (defmethod specializer<
 238     ((gf specializable-generic-function) (s1 class) (s2 class) (generalizer class))
 239   (if (eq s1 s2)
 240       '=
 241       (let ((cpl (sb-mop:class-precedence-list generalizer)))
 242         (if (find s2 (cdr (member s1 cpl)))
 243             '<
 244             '>))))
 245 (defmethod specializer<
 246     ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 sb-mop:eql-specializer) generalizer)
 247   (declare (ignore generalizer))
 248   (if (eq (sb-mop:eql-specializer-object s1) (sb-mop:eql-specializer-object s2))
 249       '=
 250       nil))
 251 (defmethod specializer< ((gf specializable-generic-function) (s1 sb-mop:eql-specializer) (s2 class) generalizer)
 252   (declare (ignore generalizer))
 253   '<)
 254 (defmethod specializer< ((gf specializable-generic-function) (c1 class) (c2 sb-mop:eql-specializer) generalizer)
 255   (declare (ignore generalizer))
 256   '>)