specializable.lisp

   1 ;;; written by David Lichteblau, based on code by Christophe Rhodes,
   2 ;;; Closette, and SBCL
   3 ;;;
   4 ;;; http://www.lichteblau.com/git/?p=specializable.git;a=blob_plain;f=specializable.lisp;hb=eb30d235951c3c1d128811278760f1db36cd336c
   5
   6 (defpackage "SPECIALIZABLE"
   7   (:use "CL" "SB-EXT")
   8   (:export "SPECIALIZABLE-GENERIC-FUNCTION" "SPECIALIZABLE-METHOD"
   9            "EXTENDED-SPECIALIZER"
  10
  11            "SPECIALIZER-ACCEPTS-P" "SPECIALIZER-ACCEPTS-CLASS-P"
  12            "SPECIALIZER<"
  13
  14            "GENERALIZER-OF-USING-CLASS"
  15            "COMPUTE-APPLICABLE-METHODS-USING-GENERALIZERS"
  16
  17            "DEFINE-EXTENDED-SPECIALIZER"))
  18
  19 (in-package "SPECIALIZABLE")
  20
  21 (defclass extended-specializer (sb-mop:specializer)
  22   ((direct-methods :initform nil
  23                    :accessor %specializer-direct-methods
  24                    :reader specializer-direct-methods)))
  25
  26 (defclass specializable-generic-function (standard-generic-function)
  27   ((extended-specializers :initform (make-hash-table :test 'equal)
  28                           :reader generic-function-extended-specializers)
  29    (emf-table :initform (make-hash-table :test 'equal) :reader emf-table))
  30   (:metaclass sb-mop:funcallable-standard-class)
  31   (:default-initargs :method-class (find-class 'specializable-method)))
  32
  33 (defclass specializable-method (standard-method)
  34   ((lambda-expression :initarg :lambda-expression
  35                       :accessor specializable-method-lambda-expression)))
  36
  37 (defmacro define-extended-specializer (name (gf-var &rest args) &body body)
  38   ;; FIXME: unparser
  39   `(setf (get ',name 'extended-specializer-parser)
  40          (lambda (,gf-var ,@args)
  41            ,@body)))
  42
  43 ;; doesn't work, because we'd have to dump GF into the fasl for the macro
  44 ;; expansion
  45 ;;; (defun intern-extended-specializer (gf sname)
  46 ;;;   (destructuring-bind (kind &rest args) sname
  47 ;;;     (setf (gethash sname (generic-function-extended-specializers gf))
  48 ;;;       (apply (or (get kind 'extended-specializer-parser)
  49 ;;;                  (error "not declared as an extended specializer name: ~A"
  50 ;;;                         kind))
  51 ;;;              gf
  52 ;;;              args))))
  53
  54 ;;; FIXME: this (and add/remove-direct-method) don't actually work
  55 ;;; together, because two distinct calls to make-extended-specializer
  56 ;;; return two distinct specializer objects.  We need either to make
  57 ;;; the extended specializers be interned, or to have them be
  58 ;;; arbitrarily ephemeral but adjust specializer-direct-methods (and
  59 ;;; implement specializer-direct-generic-functions) accordingly.
  60 (defun make-extended-specializer (sname)
  61   (destructuring-bind (kind &rest args) sname
  62     (apply (or (get kind 'extended-specializer-parser)
  63                (error "not declared as an extended specializer name: ~A"
  64                       kind))
  65            '|This is not a generic function| ;fixme, see comment above
  66            args)))
  67
  68 (defmethod sb-mop:add-direct-method ((specializer extended-specializer) method)
  69   (pushnew method (%specializer-direct-methods specializer)))
  70
  71 (defmethod sb-mop:remove-direct-method ((specializer extended-specializer) method)
  72   (setf (%specializer-direct-methods specializer)
  73         (remove method (specializer-direct-methods specializer))))
  74
  75 ;;; from SBCL:
  76
  77 (defmethod sb-pcl:parse-specializer-using-class
  78     ((gf specializable-generic-function) name)
  79   (cond
  80     ((typep name 'sb-mop:specializer) name)
  81     ((symbolp name) (find-class name))
  82     ((consp name)
  83      (case (car name)
  84        (eql (sb-mop:intern-eql-specializer (cadr name)))
  85        (t (make-extended-specializer name))))
  86     (t (error "unexpected specializer name"))))
  87
  88 (defmethod sb-pcl:make-method-specializers-form
  89     ((gf specializable-generic-function) method snames env)
  90   (declare (ignore method env))
  91   (flet ((parse (name)
  92            (cond
  93              ((typep name 'sb-mop:specializer) name)
  94              ((symbolp name) `(find-class ',name))
  95              ((consp name)
  96               (case (car name)
  97                 (eql `(sb-mop:intern-eql-specializer ,(cadr name)))
  98                 (t `(make-extended-specializer ',name))))
  99              (t (error "unexpected specializer name")))))
 100     `(list ,@(mapcar #'parse snames))))
 101
 102 ;;; from Closette, changed to use some SBCL functions:
 103
 104 ;;; FIXME: this is not actually sufficient argument checking
 105 (defun required-portion (gf args)
 106   (let ((number-required
 107          (sb-pcl::arg-info-number-required (sb-pcl::gf-arg-info gf))))
 108     (when (< (length args) number-required)
 109       (error "Too few arguments to generic function ~S." gf))
 110     (subseq args 0 number-required)))
 111
 112 ;;; FIXME: in some kind of order, the discriminating function needs to handle:
 113 ;;; - argument count checking;
 114 ;;; - keyword argument validity;
 115 ;;; - flushing the emf cache on method addition/removal
 116 ;;; - flushing the cache on class redefinition;
 117 ;;; - cache thread-safety.
 118 (defmethod sb-mop:compute-discriminating-function ((gf specializable-generic-function))
 119   (lambda (&rest args)
 120     (let* ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 121                                  (required-portion gf args)))
 122            (emfun (gethash generalizers (emf-table gf) nil)))
 123       (if emfun
 124           (sb-pcl::invoke-emf emfun args)
 125           (slow-method-lookup gf args generalizers)))))
 126
 127 (defun slow-method-lookup (gf args generalizers)
 128   ;; differs from closette
 129   (multiple-value-bind (applicable-methods definitivep)
 130       (compute-applicable-methods-using-generalizers gf generalizers)
 131     (if definitivep
 132         (let* ((emfun
 133                 (compute-effective-method-function gf applicable-methods)))
 134           (setf (gethash generalizers (emf-table gf)) emfun)
 135           (sb-pcl::invoke-emf emfun args))
 136         (sb-pcl::invoke-emf (compute-effective-method-function
 137                              gf (sb-mop:compute-applicable-methods gf args))
 138                             args))))
 139
 140 (defun compute-effective-method-function (gf methods)
 141   (let* ((mc (sb-mop:generic-function-method-combination gf))
 142          (em (sb-mop:compute-effective-method gf mc methods)))
 143     (sb-pcl::make-effective-method-function gf em)))
 144
 145 ;; new, not in closette
 146 (defgeneric generalizer-of-using-class (generic-function object))
 147 (defmethod generalizer-of-using-class ((generic-function specializable-generic-function) object)
 148   (class-of object))
 149
 150 (defgeneric specializer-accepts-generalizer-p (specializer generalizer))
 151 (defmethod specializer-accepts-generalizer-p ((specializer class) (generalizer class))
 152   ;; does the specializer's object have the -same- class as the the actual
 153   ;; argument?
 154   (if (subtypep generalizer specializer)
 155       ;; definitive: this method matches all instances of this class
 156       (values t t)
 157       ;; definitive: this method doesn't match instances of this class
 158       (values nil t)))
 159 (defmethod specializer-accepts-generalizer-p
 160     ((specializer sb-mop:eql-specializer) (generalizer class))
 161   ;; does the specializer's object have the -same- class as the actual
 162   ;; argument?
 163   (if (eq generalizer (class-of (sb-mop:eql-specializer-object specializer)))
 164       ;; not definitive, since the actual object might differ
 165       (values t nil)
 166       ;; definitely not the same object
 167       (values nil t)))
 168
 169 (defgeneric compute-applicable-methods-using-generalizers (gf generalizers))
 170 (defmethod compute-applicable-methods-using-generalizers
 171     ((gf specializable-generic-function) generalizers)
 172   ;; differs from closette
 173   (let ((result-definitive-p t))
 174     (flet ((filter (method)
 175              (every (lambda (s g)
 176                       (multiple-value-bind (acceptsp definitivep)
 177                           (specializer-accepts-generalizer-p s g)
 178                         (unless definitivep
 179                           (setf result-definitive-p nil))
 180                         acceptsp))
 181                     (sb-mop:method-specializers method) generalizers))
 182            (sorter (m1 m2)
 183              (method-more-specific-p gf m1 m2 generalizers)))
 184       (values
 185        (sort
 186         (copy-list (remove-if-not #'filter (sb-mop:generic-function-methods gf)))
 187         #'sorter)
 188        result-definitive-p))))
 189
 190 ;; new, not in closette
 191 (defgeneric specializer-accepts-p (specializer object))
 192 (defmethod specializer-accepts-p ((specializer class) object)
 193   (typep object specializer))
 194 (defmethod specializer-accepts-p ((specializer sb-mop:eql-specializer) object)
 195   (eq object (sb-mop:eql-specializer-object specializer)))
 196
 197 (defmethod compute-applicable-methods
 198     ((gf specializable-generic-function) arguments)
 199   ;; new, not in closette
 200   (sort
 201    (copy-list
 202     (remove-if-not #'(lambda (method)
 203                        (every #'specializer-accepts-p
 204                               (sb-mop:method-specializers method)
 205                               arguments))
 206                    (sb-mop:generic-function-methods gf)))
 207    (let ((generalizers (mapcar (lambda (x) (generalizer-of-using-class gf x))
 208                                (required-portion gf arguments))))
 209      (lambda (m1 m2)
 210        (method-more-specific-p gf m1 m2 generalizers)))))
 211
 212 (defun method-more-specific-p (gf method1 method2 generalizers)
 213   ;; differs from closette
 214   (declare (ignore gf))
 215   ;; FIXME: argument precedence order
 216   (block nil
 217     (mapc #'(lambda (spec1 spec2 generalizer)
 218               (ecase (specializer< spec1 spec2 generalizer)
 219                 (< (return t))
 220                 (=)
 221                 ((nil > /=) (return nil))))
 222           (sb-mop:method-specializers method1)
 223           (sb-mop:method-specializers method2)
 224           generalizers)
 225     nil))
 226
 227 ;; new, not in closette
 228 (defgeneric specializer< (s1 s2 generalizer))
 229 (defmethod specializer< ((s1 class) (s2 class) (generalizer class))
 230   (if (eq s1 s2)
 231       '=
 232       (let ((cpl (sb-mop:class-precedence-list generalizer)))
 233         (if (find s2 (cdr (member s1 cpl)))
 234             '<
 235             nil))))
 236 (defmethod specializer<
 237     ((s1 sb-mop:eql-specializer) (s2 sb-mop:eql-specializer) generalizer)
 238   (declare (ignore generalizer))
 239   (if (eq (sb-mop:eql-specializer-object s1) (sb-mop:eql-specializer-object s2))
 240       '=
 241       nil))
 242 (defmethod specializer< ((s1 sb-mop:eql-specializer) (s2 class) generalizer)
 243   (declare (ignore generalizer))
 244   '<)
 245 (defmethod specializer< ((c1 class) (c2 sb-mop:eql-specializer) generalizer)
 246   (declare (ignore generalizer))
 247   '>)